modify existing text objects

[ccowgill]

I am not sure where to go from here, I think the code I have will select a text and add a %%u in front of it to underline it, but I dont know how to get the text to actually change. Any help would be appreciated.

(defun c:cv ()
  (vl-load-com)
  (setq	SSET  (ssget (list (cons 0 "TEXT,mtext,attdef")))
	TEXT  (vlax-ename->vla-object SSET)
	TEXT2 (strcat "%%u" (vla-get-textstring TEXT))
  )
)

[ Moderator Action = ON ] What are [ CODE ] tags... [ Moderator Action = OFF ]

[Opie]

Loot into vla-put functions.

[CAB2k]

(defun c:cv (/ ss ename obj)
  (vl-load-com)
  (setq ss (ssget (list (cons 0 "TEXT,attdef")))) ; removed mtext, %%u won't work on mtext
  (and ss ; must test for nil
       (setq i -1)
       (while (setq ename (ssname ss (setq i (1+ i))))
         (setq obj (vlax-ename->vla-object ename))
         (vla-put-textstring obj (strcat "%%u" (vla-get-textstring obj)))
         (vlax-release-object obj)
       )
  )
  (princ)
)

[ccowgill]

that works great, thanks for the assistance

Is there somewhere to get a list of the vla commands, like the vla-get-textstring, I looked in the developer help, and can not find a list that tells me what they are, or how to use them

[CAB2k]

The key for me is VLIDE. If you use it as an editor it is easy to look up.
Just find the button (A) and click it. It will bring up a search dialog.
Another way is to highlight a function in the edit window then click the button.
The window that pops up will have a list of functions. Highlight one & click the
help icon in that window. Another is to highlight part of a function & click the
(A) button. Play with it.