Convert Aligned Dimensions to Rotated Dimensions

[CADdancer]

Good Morning To AUGI Members:

Is there a way to convert Aligned dimensions on a drawing to Rotated dimensions...??...

We receive drawings from a consultant that have both Aligned and Rotated dimensions and I want to isolate the Aligned dimensions and convert them into Rotated dimensions. The reason for this replacement is to allow us to shorten or extend the dimension extension lines without disturbing the alignment (orientation) of the dimension line and text string that will occur on an Aligned dimension if you move either of the original attachment points.

Could this be accomplished with a lisp routine...??

If this is difficult to do can a selection set of just the Aligned dimensions be created with a lisp routine...??

Any assistance with this matter would be appreciated.

Regards,
Vince

[Opie]

Vince,

I'll see what I can come up with this evening on changing aligned dimensions to rotated dimensions.

For the mean time, I would suggest you look into searching the forums for "filter selection sets". This thread (Mirror a Drawing but not the xrefs. filter selection sets) will give you a start on selection set filters.

[T.Willey]

Here is a start.

(defun c:ChangeDimObject (/ Sel EntData Pt1 Pt2 Pt3)

(setq Sel (entsel "\n Select dimension object: "))
(setq EntData (entget (car Sel)))
(setq Pt1 (cdr (assoc 13 EntData)))
(setq Pt2 (cdr (assoc 14 EntData)))
(setq Pt3 (cdr (assoc 11 EntData)))
(if (< (car Pt1) (car Pt2))
 (command "_.ucs" "_3" Pt1 Pt2 (polar Pt1 (+ (DTR 90) (angle Pt1 Pt2)) 5))
 (command "_.ucs" "-3" Pt2 Pt1 (polar Pt2 (+ (DTR 90) (angle Pt2 Pt1)) 5))
)
(entdel (car Sel))
(command "_.dim" "_horizontal" (trans Pt1 0 1) (trans Pt2 0 1) (trans Pt3 0 1) "" "_exit")
(command "_.ucs" "_p")
)

I think it does most of what you want it to do. You can get a selection set, and cycle through the selection set with this code, and it should work.

Tim

[CADdancer]

Hello Tim:

Thank you for your quick response.......Your example works great however, it will attempt to convert all dimension types not just Aligned dimensions. Do you know how to build a selection set for just Aligned dimensions only...??

Any input will be appreciated.

Regards,
Vince

[T.Willey]

I don't think you can build a selection set for just aligned dimensions. I think you will have to build a selection set of dimensions, and then cycle through each one, test to make sure it is an aligned one, and then run the code posted.

If you need futur help post, and I will see if I can get you something today.

Tim

[T.Willey]

This should work. Note it will draw the new dimension on the current layer, with the current dim style.

(defun c:ChangeDimObject (/ ss Ent EntData Pt1 Pt2 Pt3)

(setq ss (ssget '((0 . "DIMENSION"))))
(while (setq Ent (ssname ss 0))
 (setq EntData (entget Ent))
 (if (not (member '(100 . "AcDbRotatedDimension") EntData))
  (progn
   (setq Pt1 (cdr (assoc 13 EntData)))
   (setq Pt2 (cdr (assoc 14 EntData)))
   (setq Pt3 (cdr (assoc 11 EntData)))
   (if (< (car Pt1) (car Pt2))
    (command "_.ucs" "_3" Pt1 Pt2 (polar Pt1 (+ (DTR 90) (angle Pt1 Pt2)) 5))
    (command "_.ucs" "-3" Pt2 Pt1 (polar Pt2 (+ (DTR 90) (angle Pt2 Pt1)) 5))
   )
   (entdel Ent)
   (command "_.dim" "_horizontal" (trans Pt1 0 1) (trans Pt2 0 1) (trans Pt3 0 1) "" "_exit")
   (command "_.ucs" "_p")
  )
 )
 (ssdel Ent ss)
)
)

Tim

[T.Willey]

Okay. Here is the final version that I am putting into my lisp routines. If there is any problem let me know.

(defun c:ChangeDimObject (/ ss Ent EntData Pt1 Pt2 Pt3 ocmd omode olay odim)
; Redraw dimension that were drawn as aligned as rotated on correct layer, and with correct dimension style.

(setq ocmd (getvar "cmdecho"))
(setvar "cmdecho" 0)
(command "_.undo" "_end")
(command "_.undo" "_begin")
(setq omode (getvar "osmode"))
(setvar "osmode" 0)
(setq olay (getvar "clayer"))
(setq odim (getvar "dimstyle"))
(if (setq ss (ssget '((0 . "DIMENSION"))))
 (while (setq Ent (ssname ss 0))
  (setq EntData (entget Ent))
  (if (not (member '(100 . "AcDbRotatedDimension") EntData))
   (progn
    (setq Pt1 (cdr (assoc 13 EntData)))
    (setq Pt2 (cdr (assoc 14 EntData)))
    (setq Pt3 (cdr (assoc 11 EntData)))
    (if (< (car Pt1) (car Pt2))
     (command "_.ucs" "_3" Pt1 Pt2 (polar Pt1 (+ (DTR 90) (angle Pt1 Pt2)) 5))
     (command "_.ucs" "_3" Pt2 Pt1 (polar Pt2 (+ (DTR 90) (angle Pt2 Pt1)) 5))
    )
    (setvar "clayer" (cdr (assoc 8 EntData)))
    (command "_.dimstyle" "_r" (cdr (assoc 3 EntData)))
    (entdel Ent)
    (command "_.dim" "_horizontal" (trans Pt1 0 1) (trans Pt2 0 1) (trans Pt3 0 1) "" "_exit")
    (command "_.ucs" "_p")
   ) 
  )
  (ssdel Ent ss)
 )
)
(command "_.dimstyle" "_r" odim)
(command "_.undo" "_end")
(setvar "clayer" olay)
(setvar "osmode" omode)
(setvar "cmdecho" ocmd)
(princ)
)

Tim

[fixo]

Hi Tim

Nice work

Thank you

f.

[CADdancer]

Hello Tim:

The code looks great but I am getting an error message "No function DTR".

Any thoughts.....??

[fixo]

Hi Vince

You can change (dtr 90) on: (/ pi 2)

f.