aec_curvetext orientation

[chrisw.94380]

I am using Land Desktop 2005 and am having trouble when I am labeling curves. Basically when I label curves it creates aec_curvetext. I am not able to rotate or flip the text so that I can orientate it corrrectly. I have searched the Land Desktop forum and found others to have the same problem. Does anyone have a lisp routine that they currently use for this because I am sure it would be helpful not only to myself but to others on AUGI and if not does anyone have any ideas of how to go about this. Thank you

[Jeff_M]

Hi Chris, I have been unable to trick the CurveText into flipping. I have written a small routine that converts the CurveText to MText. This makes it easy to move/rotate but it's no longer aligned with the curve. If you would like it just let me know.

Jeff

[chrisw.94380]

I haven't had any luck either so I guess it is back to the drawing board. Is this something that you also have a problem with?

[Capo De Capo]

Hi Chris, I have been unable to trick the CurveText into flipping. I have written a small routine that converts the CurveText to MText. This makes it easy to move/rotate but it's no longer aligned with the curve. If you would like it just let me know.

Jeff

I would be very intersted in seeing this code, if you would share with me. I have same problem as viewport is not always twisted the same as the model orientation. Any help would be greatly appreciated. Thanks In Advance!

[Jeff_M]

Here ya go!

;;Function to convert Curve Text created by LandDesktop labels into MTEXT objects
;;by Jeff Mishler August 2005
(defun c:ctxt2mtxt (/ ang doc ent inspt mtxt obj space ss styl txt1 txt2)
  (if (not (setq ss (ssget ":S" '((0 . "AEC_CURVETEXT")))))
    (alert "You must select AEC_CURVETEXT to use this function!")
    (progn
      (setq ent (ssname ss 0)
	    obj (vlax-ename->vla-object ent)
	    ent (entget ent)
	    doc (vla-get-activedocument (vlax-get-acad-object))
	    space (if (= (getvar "cvport") 1)
		    (vla-get-paperspace doc)
		    (vla-get-modelspace doc)
		    )
	    txt1 (vlax-get obj 'textabove)
	    txt2 (vlax-get obj 'textbelow)
	    styl (cdr (assoc 7 ent))
	    inspt (cdr (assoc 11 ent))
	    ang (cdr (assoc 54 ent))
	    )
      (setq mtxt (vlax-invoke space 'addmtext inspt 0 (strcat txt1 "\\P" txt2)))
      (vla-put-stylename mtxt styl)
      (vla-put-layer mtxt (vla-get-layer obj))
      (vla-put-height mtxt (cdr (assoc 40 ent)))
      (vla-put-rotation mtxt (- ang (/ pi 2)))
      (vla-put-attachmentpoint mtxt acAttachmentPointMiddleCenter)
      (vlax-put mtxt 'insertionpoint inspt)
      (vla-delete obj)
      )
    )
  (princ)
  )

[Capo De Capo]

Thanks a bunch Miff, I actually found this same code over on ADG, did you post that there too. LOL!


Thanks again,