Problem with the result of vlax-get-property

[GreyHippo]

I am trying to get the start point of a line object and I used the following code

(setq start_pt (vlax-get-property obj 'StartPoint))

but when I (princ start_pt)

I get "#<variant 8197 ...>"

Do I need to do anything to the variable to turn it into a point list?

[dmarcotte4]

Try

(vlax-variant-value start_pt )

Dan

[GreyHippo]

Dan, when I use that I get an error

; error: ActiveX Server returned the error: unknown name:

[fixo]

Try this instead

(vl-load-com)
....................
(setq start_pt  (vlax-get obj 'StartPoint))
(princ start_pt)

~'J'~

[kennet.sjoberg]

Try
(setq start_pt (vlax-get Obj 'StartPoint ) )
or
(setq start_pt (vlax-get Obj "StartPoint" ) )

: ) Happy Computing !

kennet

[jwanstaett]

this testit fuction show how to get the startpoint of a line to a list
the code well error IFa line, arc or ellipse is not select

(defun c:testit()
(setq entname (car (entsel)));get entity name
(setq obj (vlax-ename->vla-object entname));set to a vla-object
(setq sp (VLA-GET-STARTPOINT obj));get the startpoint this is a variant
(setq sp2 (vlax-variant-value sp));get the value of the variant this is a safearray
(setq sp3 (vlax-safearray->list sp2));change the safearray to a list
;;the next line dose it in one line
(setq x (vlax-safearray->list(vlax-variant-value(vla-get-startpoint obj))))
)

[GreyHippo]

I got it to work with the following code. The finished product is not complete yet but this is a start.

(defun dtr (a)
(* (/ a 180.00) pi)
   )


(defun rtd (a)
  (* (/ a pi) 180.0)
  )

(defun c:bad_pick (/ obj start_pt end_pt length_obj angle_obj midpt)
  	(setq obj (car (entsel "\nSelect Line Object: ")))
  	(setq obj (vlax-ename->vla-object obj))
      	(vl-load-com)
      	(setq start_pt (vlax-safearray->list (vlax-variant-value (vlax-get-property obj 'StartPoint))))
  	(setq end_pt (vlax-safearray->list (vlax-variant-value (vlax-get-property obj 'EndPoint))))
  	(setq length_obj (vlax-get-property obj 'Length))
      	(setq angle_obj (vlax-get-property obj 'Angle))
	(setq midpt (polar start_pt angle_obj (/ length_obj 2)))


	(setq l_obj (strcat (rtos length_obj 2 2) "\'"))
      	(setq a_obj (angtos angle_obj 4 4))
      	(setq a_obj (vl-string-subst "%%d" "d" a_obj))
      	(command "mtext" midpt "r" (rtd angle_obj) "j" "mc" "w" "0" a_obj l_obj "")


(princ)
)

[Jeff_M]

Hi boesiii,
Since you are using ActiveX for most of your routine, here's the missing part to take the creation of the Mtext from the command function to ActiveX.....

      	;(command "mtext" midpt "r" (rtd angle_obj) "j" "mc" "w" "0" a_obj l_obj "")
  (setq *doc* (vla-get-activedocument (vlax-get-acad-object))) 
  (setq mtxt (vlax-invoke
	       (vla-objectidtoobject *doc* (vla-get-ownerid obj))
	       'addmtext
	       midpt
	       0
	       (strcat a_obj "\\P" l_obj)
	       ))
  (vla-put-attachmentpoint mtxt acAttachmentPointMiddleCenter)
  (vlax-put mtxt 'insertionpoint midpt)
  (vla-put-rotation mtxt angle_obj)