Error "library not registered" when trying to run LISP routine (LDT related)

[Hammer.John.J]

for some reason one of my associates gets this "library not registered" error when trying to use the following lisp and blocks

it obviously recognizes the lisp because it thinks, for a millisecond then errors that message.

These exact same routines work on my pc, what the heck? is this cui related or something. I've loaded the lisp every way possible with the same result.

[Jeff_M]

Open the Lisp in the VLIDE, place a breakpoint near the beginning of the routine, run it from ACAD, once it hits the breakpoint use the F8 key to step through and find which line it errors on.....

Although you might try adding (vl-load-com) to the beginning....

[Hammer.John.J]

thanks miff,

i'll try that when i get to work, what does that mean anyways?

[Opie]

thanks miff,

i'll try that when i get to work, what does that mean anyways?

It allows you to step through the routine one expression at a time.

You should look at the Debug menu for "Watch Last Expression". It will open another window and show you the result of the last expression.

[Hammer.John.J]

ok i did the watch and this is what i get

Welcome to Visual LISP for AutoCAD 2006
; LPP kernel: IDE v.T.0* Mar 5 2005
[ACADVER = 16.2s (LMS Tech)]
; kern VLLib: IDE v.T* Mar 03 1999, build #690 [3/5/05]

; "C:/Program Files/Autodesk Land Desktop 2006/VLLIB.DLL" loaded
; desktop restored from "C:/Documents and Settings/dank.OFFICE/Application Data/Autodesk/Autodesk Land Desktop 2006/R16.2/enu/VLIDE.DSK"
...............
LOG Watch
...............
SPTL40 = nil
...............


I can't figure out why it errors on everyone elses machine except mine? I also tried adding the (v-load-com) at the first line of the lisp and got the exact same error.

[Hammer.John.J]

(defun attsurf	(bname / acadobj aecapp aecProj aecsurfs aecsurf aecutil e-n
		 emsg pt# selev appstr versn *error* att blk space)
  (defun *error* (msg / objlist)
    (setq objList
	   (reverse
	     (list acadobj aecapp aecProj aecsurfs aecsurf aecutil)
	   )
    )
    (vl-catch-all-apply
      '(lambda ()
	 (mapcar 'vlax-release-object objlist)
       )
    )
    (if	msg
      (princ (strcat "\n" msg))
    )
    (princ)
  )
  ;;;;;
  (setq appstr (cond ((= (setq versn (atoi (substr (getvar "acadver") 1 2))) 15) "2")
		     ((= versn 16) "4")
		     ((= versn 17) "6")
		     )
	)
  (setq	acadObj	 (vlax-get-acad-object)
	space    (vla-get-modelspace (vla-get-activedocument acadObj))
	aecApp	 (vla-getinterfaceobject acadObj (strcat "Aecc.Application." appstr))
	aecProj	 (vlax-get aecApp "Activeproject")
	aecSurfs (vlax-get aecProj "Surfaces")
	aecSurf	 (vlax-get aecSurfs "Currentsurface")
	aecUtil	 (vlax-get (vlax-get aecApp "activedocument") "Utility")
  )
  (if (and (= aecSurf "")
	   (> (vlax-get aecSurfs "count") 0)
      )
    (setq aecSurf (vlax-get (vlax-invoke aecSurfs "item" 0) "name"))
  )
  (if (= aecSurf "")
    (princ
      "\nNo surfaces defined, try again after creating a surface."
    )
    (progn
      (setq aecSurf (vlax-invoke aecSurfs "item" aecSurf))
      (while (setq
	       pt# (getpoint "\nPoint to label on the current surface: ")
	     )
	(setq e-n (vlax-invoke aecutil "xytoeastnorth" pt#))
	(setq selev (vlax-invoke
		      aecSurf
		      "getelevation"
		      (car e-n)
		      (cadr e-n)
		    )
	)
	;;Insert your block insertion and attribute setting here
	(setq blk (vlax-invoke space 'insertblock pt# bname 1.0 1.0 1.0 0.0))
	(setq att (car (vlax-invoke blk 'getattributes)))
	(vla-put-textstring att (rtos selev 2 2))
	;(princ (strcat "\nElevation at point = " (rtos selev)))
      )
    )
  )
  (*error* nil)
)


;;;make as many of these as you need, this is for the SPOTL40 block
(defun c:SPOTL (/ bname)
  (setq bname "sptl40");;set the block name in this line
  (if (or (tblsearch "BLOCK" bname)
	  (setq bname (findfile bname))
	  )
    (attsurf bname)
    )
  (princ)
  )

[Jeff_M]

All other machines are also running some version of LDT (3 - 2007)? Could you post the results of the following 2 lines, run at the command line, from at least 2 of the problem computers?

(getvar "acadver")
(vlax-product-key)

[Hammer.John.J]

my pc
Command: (getvar "acadver")
"16.2s (LMS Tech)"
Command: (vlax-product-key)
"Software\\Autodesk\\AutoCAD\\R16.2\\ACAD-4008:409"

pc1
Command: (GETVAR"ACADVER")
"16.2s (LMS Tech)"
Command: (GETVAR"ACADVER")(VLAX-PRODUCT-KEY)
"Software\\Autodesk\\AutoCAD\\R16.2\\ACAD-4008:409"


pc2
Command: (GETVAR "ACADVER")
"16.2s (LMS Tech)"
Command: (VLAX-PRODUCT-KEY)
"Software\\Autodesk\\AutoCAD\\R16.2\\ACAD-4008:409"

pc3
Command: (getvar "acadver")
"16.2s (LMS Tech)"
Command: (vlax-product-key)
"Software\\Autodesk\\AutoCAD\\R16.2\\ACAD-4008:409"

[Jeff_M]

Hmm, I'm re-installing 2006 now to see if I can track this down......

[Hammer.John.J]

wicked odd. there must be something on my pc that is not on the others? or the lisp is not finding the blocks in the drawing? i don't even know what that error means.