Run PLINE command with Endpoint Osmode on as I pick different parts in drawing

[cadd4la]

Hi everyone,

I having a problem with this code that I am trying to write. I am looking to have it run the pline command with the endpoint osmode on as I pick different parts of my drawing.

The way it is written now it will pick the first two point but after that it will not use the endpoint osmode.

I hope somebody can help me

Thanks,

Kyle C.

(DEFUN C:PL1 (/ *Error* useros usercmd)
  ;; error function & Routine Exit
  (defun *error* (msg)
	(if
	  (not
 (member
   msg
   '("console break"
	 "Function cancelled"
	 "quit / exit abort"
	 ""
	)
 )
	  )
	   (princ (strcat "nError: " msg))
	); endif
	;;reset all variables here
	(if useros
	  (setvar "osmode" useros)
	)
	(if usercmd
	  (setvar "CMDECHO" usercmd)
	)
	(setq useros nil
   usercmd nil
	)
  );end error function  (defun *Error* (msg) ; embedded defun

  (setq useros (getvar "osmode")
 usercmd (getvar "CMDECHO")
  )
  (setvar "cmdecho" 0)
  (setq os1 (getvar "osmode"))
  (princ "MACRO: PLINE WITH ENDPOINT ON")
  (setvar "osmode" 1)
  (COMMAND "_PLINE" (getpoint "nPick First point: "))
  ;(while (> (getvar "cmdactive") 0)) ; I am not sure if I need this or not, if I use it, it locks up Autocad
  (princ "nNext Point: ");let 'em know it wants another point
  (command pause);pause for subsiquent points
  (setvar "osmode" os1)
  (SETVAR "CMDECHO" 1)
  (princ)
)

[madcadder]

 (DEFUN c:pl1 (/ *error* useros usercmd)
   ;; error function & Routine Exit
   (DEFUN *error* (msg)
 	(IF
 	  (NOT
 	(MEMBER
 	  msg
 	  '("console break"
 		"Function cancelled"
 		"quit / exit abort"
 		""
 	   )
 	) ;_ end of member
 	  ) ;_ end of not
 	   (PRINC (STRCAT "nError: " msg))
 	)					; endif
 	;;reset all variables here
 	(IF	useros
 	  (SETVAR "osmode" useros)
 	) ;_ end of if
 	(IF	usercmd
 	  (SETVAR "CMDECHO" usercmd)
 	) ;_ end of if
 	(SETQ useros nil
 	  usercmd nil
 	) ;_ end of setq
   )					;end error function  (defun *Error* (msg) ; embedded defun
 
   (SETQ	useros	(GETVAR "osmode")
 	usercmd	(GETVAR "CMDECHO")
   ) ;_ end of setq
   (SETVAR "cmdecho" 0)
   (SETQ os1 (GETVAR "osmode"))
   (PRINC "MACRO: PLINE WITH ENDPOINT ON")
   (SETVAR "osmode" 1)
   (COMMAND "_PLINE" (GETPOINT "nPick First point: "))
   (WHILE (> (GETVAR "cmdactive") 0)
 	(PRINC "nNext Point: ")
 	(COMMAND pause)
   ) ;_ end of while
   (SETVAR "osmode" os1)
   (SETVAR "CMDECHO" 1)
   (PRINC)
 ) ;_ end of DEFUN

tested and works with this mod.

EDIT: You are setting OSMODE to two different variables.

[cadd4la]

Tod,

Thank you for your help.

Kyle C.