Select a point vs. String input

[garberadam]

Is there a way to have the user either select a point or input a keyword during a lisp routine?... i.e. the pline command... once started you can continue selecting points or you can type "arc" or such and then continue selecting points. Thanks.

[Adesu]

Higarberadam,
for this question
"Is there a way to have the user either select a point or input a keyword during a lisp routine?... "
you can use
1). (setq ss (car (entsel "\nSelect a object")))
2). (setq ss (ssget "x" '((0 . "LINE,PLINE",ARC....etc"))))

for others question,I'm cannot answerd,because rather confuse (maybe I stupid).

Is there a way to have the user either select a point or input a keyword during a lisp routine?... i.e. the pline command... once started you can continue selecting points or you can type "arc" or such and then continue selecting points. Thanks.

[garberadam]

I'm sorry i guess i was confusing earlier.... what i want is for the user to be able to pick points to draw a line.... then type a string.... then go back to picking points.....
If i use the getpoint command i can't input a string... if i use the getstring i can't pick a point with the cursor.. how do i enable both at the same time?... sorry for the confusion.. i don't know if my explanation helps... i guess i just want to redo the polyline command.. with my own options...... i don't know how else to explain it though....

[Adesu]

Hi garberadam,
do you mean like this

(defun c:test (/ cth p1 p2 p3 str cth th)
  (while
    (setq p1 (getpoint "\nClick any location<0,0,0>: "))
    (if (= p1 "")(setq p1 '(0 0 0)))
    (setq p2 (getpoint p1"\nClick any location<0,0,0>: "))
    (if (= p2 "")(setq p2 '(10 0 0)))
    (command "_line" p1 p2 "")
    (setq str (getstring "\nEnter new string: "))
    (setq p3 (getpoint "\nClick where to put string: "))
    (setq cth (getvar "textsize"))
    (setq th (getdist (strcat "\nEnter text height< " (rtos cth) " >: ")))
    (if (= th nil)(setq th cth))
    (command "_text" p3 th "" str 0)
    )
  (princ)
  )

I'm sorry i guess i was confusing earlier.... what i want is for the user to be able to pick points to draw a line.... then type a string.... then go back to picking points.....
If i use the getpoint command i can't input a string... if i use the getstring i can't pick a point with the cursor.. how do i enable both at the same time?... sorry for the confusion.. i don't know if my explanation helps... i guess i just want to redo the polyline command.. with my own options...... i don't know how else to explain it though....

[kennet.sjoberg]

This is the solution

(command "._pline" ) (while (= 1 (logand (getvar "CMDACTIVE") 1 )) (command PAUSE ) )

: ) Happy Computing !

kennet

[Opie]

I'm sorry i guess i was confusing earlier.... what i want is for the user to be able to pick points to draw a line.... then type a string.... then go back to picking points.....
If i use the getpoint command i can't input a string... if i use the getstring i can't pick a point with the cursor.. how do i enable both at the same time?... sorry for the confusion.. i don't know if my explanation helps... i guess i just want to redo the polyline command.. with my own options...... i don't know how else to explain it though....

From AutoCAD Developer's Help, look at the arbitrary keyboard input.

(defun C:ARBENTRY ( / pt1) 
  (initget 128)                     ; Sets arbitrary entry bit 
  (setq pt1 (getpoint "\nPoint: ")) ; Gets value from user. 
  (if (= 'STR (type pt1))           ; If it's a string, convert it
    (setq pt1 (eval (read pt1)))    ; to a symbol, try evaluating
                                    ; it as a function; otherwise,
    pt1                             ; just return the value. 
  )
)
(defun REF ( )
  (setvar "LASTPOINT" (getpoint "\nReference point: "))
  (getpoint "\nNext point: " (getvar "LASTPOINT"))
)

[CAB2k]

This is an option, although it will not allow the space character. Single words only.
If you need spaces in the text you will have to use grread.

(defun c:getline (/ pt1 strlst pstart)
  (while
    (cond
      ((progn
         (initget 128)
         (null
           (if pstart
             (setq pt1 (getpoint pstart "\nSelect Next Point or enter Text: "))
             (setq pt1 (getpoint "\nSelect 1st Point or enter Text: "))
           )
         )
       )
       nil     ; exit loop
      )
      ((= 'STR (type pt1)) ; collect user input
       (setq strlst (cons  pt1 strlst))
      )
      ((= 'LIST (type pt1))
       (if pstart
         (command "_.line" pstart pt1 "")
       )
       (setq pstart pt1)
      )
    )
  )
  strlst ; return a list of the keyword strings entered by the user
)

[pnorman]

I think the answer to your question is the "initget" function?! It is specifically designed to do exactly what you want. What you do with the user input is up to you. You have to write the necessary code using while, if and/or cond etc to handle the user input.

Here is an example:

  (while (/= (type INSPT) 'LIST)
	(initget "T M B O")
	(setq INSPT (getpoint PT1 "\nInsert point or [Top/Middle/Bottom](Options...): "))
	(cond
	  ((= INSPT "T")
	   (setq PT1 SP)
	  )
	  ((= INSPT "M")
	   (setq PT1 (list (car SP) (- (cadr SP) (/ D 2.00)) (caddr SP)))
	  )
	  ((= INSPT "B")
	   (setq PT1 (list (car SP) (- (cadr SP) D) (caddr SP)))
	  )
	  ((= INSPT "O")
	   (setq WHAT_NEXT 2 INSPT '(0 0))
	   (ppn:vla-delete-ss SS1)
	  )
	  ((= INSPT nil)
	   (setq WHAT_NEXT 0 INSPT '(0 0))
	   (ppn:vla-delete-ss SS1)
	  )
	)
  )

[garberadam]

THANK YOU THANK YOU THANK YOU..... you guys are great!!!!!!!!!!!