AutoCAD to Excel - error: Automation Error. Description was not provided

[vkotesh]

While updating the data from AutoCAD to Excel I am getting message.
; error: Automation Error. Description was not provided.

Can anybody suggest me to overcome this

I am using AutoCAD Map 6.0 and Microsoft Excel 2002(10.2614.3501)SP-1

and I tried like this...

;----------------------------------------------------------------------------------------------------------------------;
; Routine to update data from autocad to excel.
;----------------------------------------------------------------------------------------------------------------------;
(defun C:Uv
	  ()
	  (if (setq excelObj (vlax-get-object "Excel.Application"))
       	  (if (169::ImportExcelLibrary (vlax-get-property excelObj 'Path))
	  (progn
	  (setq bookObj  (vlax-get-property excelObj 'ActiveWorkBook)
		sheetObj (ExcelP-get-ActiveSheet bookObj)
		rangeObj (ExcelP-get-Range sheetObj "A1")
	  );setq
                  ;********** Error Position**************
	  (ExcelP-put-Value rangeObj "Sample Text")
	  ; error: Automation Error. Description was not provided.

	  (vlax-release-object sheetObj)
	  (vlax-release-object bookObj)
	  (vlax-release-object excelObj)
	  );progn
	  );if
	  );if
(princ)
);defun

;----------------------------------------------------------------------------------------------------------------------;
; Function to import Excel library.
;----------------------------------------------------------------------------------------------------------------------;
(defun 169::ImportExcelLibrary
	  (libraryPath)
  	  (if (null(member "EXCELP-GET-ACTIVESHEET" (atoms-family 1)))
	  (vlax-import-type-library :tlb-filename (strcat libraryPath "Excel.exe")
	    			    	:methods-prefix "ExcelM-"
	    			        :properties-prefix "ExcelP-"
	    			        :constants-prefix "ExcelC-")
	  T
	  );if
);defun

[ Moderator Action = ON ] What are [ CODE ] tags... [ Moderator Action = OFF ]

[kennet.sjoberg]

Try
(ExcelP-put-Value2 rangeObj "Sample Text")

: ) Happy Computing !

kennet

[peter]

Try this

(setq excelObj (vlax-get-object "Excel.Application.10"))

Also here is a routine that I use that works for importing excel data to a list.

Peter

[kennet.sjoberg]

. . .Also here is a routine that I use that works for importing excel data to a list.

Peter

Peter, do you have a way to kill the EXCEL.EXE process after your routine is finished ?
otherwise Excel is still running until you exit AutoCAD
you can see that in the [Ctrl+Alt+Delete] Program Manager, tab Processes.

: ) Happy Computing !

kennet

[peter]

Try this revised version.

Peter

[kennet.sjoberg]

Try this revised version.

Peter

No, Excel is still active until I exit AutoCAD , please see attachment

BTW typo at this line
(errortrrap '(xlm-close objWBook))
(errortrap '(xlm-close objWBook))

: ) Happy Computing !

kennet

[fixo]

This has worked for me as you want:

(defun EXD (/ ExcelApp ExcData FilePath Sht ShtNum UsdRange Wbk)

  (vl-load-com)
  (setq	FilePath (getfiled "Select Excel file to read :"
			   (getvar "dwgprefix")
			   "xls"
			   16
		 )
  )

  (setq ShtNum (getint "\nEnter sheet number : \n"))

  (setq ExcelApp (vlax-get-or-create-object "Excel.Application"))
  (vla-put-visible ExcelApp :vlax-true)
  (setq	Wbk (vl-catch-all-apply
	      'vla-open
	      (list (vlax-get-property ExcelApp "WorkBooks") FilePath)
	    )
  )
  (setq	Sht (vl-catch-all-apply
	      'vlax-get-property
	      (list (vlax-get-property Wbk "Sheets")
		    "Item"
		    ShtNum
	      )
	    )
  )
  (vlax-invoke-method Sht "Activate")
  (setq	UsdRange (vlax-get-property Sht 'UsedRange)
	ExcData	 (vlax-safearray->list
		   (vlax-variant-value
		     (vlax-get-property UsdRange 'Value)
		   )
		 )
  )					;or Value2
  (setq
    ExcData (mapcar
	      (function (lambda (x) (mapcar 'vlax-variant-value x)))
	      ExcData
	    )
  )

  (vl-catch-all-apply
    'vlax-invoke-method
    (list Wbk "Close")
  )

  (vl-catch-all-apply
    'vlax-invoke-method
    (list ExcelApp "Quit")
  )

  (mapcar
    (function
      (lambda (x)
	(vl-catch-all-apply
	  (function (lambda ()
		      (progn
			(if (not (vlax-object-released-p x))
			  (progn
			    (vlax-release-object x)
			    (setq x nil)
			  )
			)
		      )
		    )
	  )
	)
      )
    )

    (list UsdRange Sht Wbk ExcelApp)
  )

  (gc)
  (gc)
  ExcData

)
;  CaLL :
; (setq somedata (exd))

~'J'~

[kennet.sjoberg]

peter and fixo . . .the (gc) fixed it !

When I put (gc) secondlast in Peters code, Excel will quit . . .

|
|
|
(gc)
 (if lstOfSublists lstOfSublists)
)

: ) Happy Computing !

kennet