Automate addition of text objects in columns into a "Total" column

[ermbjf]

I have a electrical riser diagram (which looks like a schedule) and I would like to automate the addition of the text to add up the columns into a "Total" column? I'm looking for a lisp or something that would add this text up and automatic update itself if changes occur... does anyone have any other ideas??

[RobertB]

Your posted description is not complete enough to give us anything to work with. I doubt you will get many responses until you provide detailed information.

[ermbjf]

The riser diagram is like a spread sheet. You have text that are all number data that is added up at the bottom. These answers are then relocated to its sister column and add to that column. This answer is then divided by 120 to get the amps.

[RobertB]

Why not just do the schedule in Excel and OLE the spreadsheet in? Or in 2005, you can paste the spreadsheet as AutoCAD Entities which brings it in as a Table object.

[ermbjf]

I using 3.3 ADT, also if I used excel how would I get the excel data located in the right spots with out re inputing this data.

[RobertB]

See, that's what I stated in my first post: you aren't giving us enough information. What types of objects make up the schedule? ADT objects? Blocks? MText? What does this thing look like?

We are an M/E/P firm, and we do our electrical panel schedules in Excel from day one, then just link them into the drawing. I've never seen an electrical riser diagram that looked like a schedule.

[ermbjf]

attached is a drawing

[peter]

Load this routine in this drawing. Do not run the routine, I already have.

Change a number on the chart.

It should change the totals

Peter Jamtgaard

(defun C:Riser3 (/ intCount entSelection lstEntity lstObjects objSelection ssSelections )
 (setq blnChangeText nil)
 (while (setq dprTotal (entsel "\nSelect text for total: "))
  (setq strGroup (strcase (substr (getstring "\nEnter Group Letter: ") 1 1)))
  (setq objTotal (vlax-ename->vla-object (car dprTotal)))
  (vlax-ldata-put objTotal "total" strGroup)
  (if (wcmatch (strcase (vla-get-objectname objTotal)) "*TEXT")
   (progn
    (setq ssSelections (ssget (list (cons 0 "*TEXT")))
          lstHandles   nil
    )
    (repeat (setq intCount (sslength ssSelections))
     (setq intCount     (1- intCount)
           entSelection (ssname ssSelections intCOunt)
           objSelection (vlax-ename->vla-object entSelection)
           lstObjects   (cons objSelection lstObjects)
     )
     (vlax-ldata-put objSelection "item" strGroup)   
    )
    (setObjectReactorRiser lstObjects)
    (setq lstObjects nil)
   )
  )
 )
 (princ)
)
(defun SetObjectReactorRiser (lstObjects)
 (if (not rxnRiser)   
  (setq rxnRiser        (vlr-object-reactor lstObjects "Riser" 
                                                       '((:vlr-Modified  . Riser2)))
        rxnComEndRiser  (vlr-editor-reactor nil '((:vlr-commandended . Riser3)))
  )
  (foreach objLayer lstObjects
   (vlr-owner-add rxnRiser objLayer)
  )
 )
)

; Object Reactor
(defun Riser2 (objOwner objReactor lstEntity)
 (if (not RerunRiser)
  (if (vlax-ldata-get objOwner "item")
   (setq blnChangedText 'T)
  )
 )
)

; Command Ended Reactor
(defun Riser3 (CALL CALLBACK / lstGroups)
 (if blnChangedText
  (foreach strGroup (getGroupLetters)
   (setq RiserRerun 'T)
   (setTotal strGroup) 
   (setq RiserRerun nil)
  )
 )
 (setq blnChangeText nil)
)

(defun getGroupLetters (/ lstGroupLetters strGroupLetter)
 (vlax-for objLayout (vla-get-layouts
                      (vla-get-activedocument
                       (vlax-get-acad-object)
                      )
                     )
  (vlax-for objBlock (vla-get-block objLayout)
   (if (wcmatch (strcase (vla-get-objectname objBlock)) "*TEXT")
    (if (setq strGroupLetter (vlax-ldata-get objBlock "total"))
     (if (not (member strGroupLetter lstGroupsLetters))
      (setq lstGroupLetters (cons strGroupLetter lstGroupLetters))
     )
    )
   )
  )
 )
 (if lstGroupLetters 
  (acad_strlsort lstGroupLetters)
 )
)

(defun setTotal (strGroup / dblTotal lstObjects objTotal )
 (setq dblTotal 0)
 (vlax-for objLayout (vla-get-layouts
                      (vla-get-activedocument
                       (vlax-get-acad-object)
                      )
                     )
  (vlax-for objBlock (vla-get-block objLayout)
   (if (wcmatch (strcase (vla-get-objectname objBlock)) "*TEXT")
    (if (= strGroup (vlax-ldata-get objBlock "item"))     
     (setq lstObjects (cons objBlock lstObjects))
     (if (= strGroup (vlax-ldata-get objBlock "total"))
      (setq objTotal objBlock)
     )
    )
   )
  )
 )
 (if (and lstObjects objTotal)
  (progn
   (foreach objText lstObjects
    (setq dblTotal (+ dblTotal (atof (vla-get-textstring objText))))
   )
   (vla-put-textstring objTotal (itoa (fix dblTotal)))
  )
 )
)
 

(defun StartRiser (/ lstObjects)
 (vlax-for objLayout (vla-get-layouts
                      (vla-get-activedocument
                       (vlax-get-acad-object)
                      )
                     )
  (vlax-for objBlock (vla-get-block objLayout)
   (if (wcmatch (strcase (vla-get-objectname objBlock)) "*TEXT")
    (if (setq strGroup (vlax-ldata-get objBlock "item"))
     (progn
      (setq lstObjects (cons objBlock lstObjects))      
     )
    )
   )
  )
 )
 (setObjectReactorRiser lstObjects)
)
(startriser)

[ermbjf]

Peter; I tried to load the drawing but get a compatible message, could you save it as a ACAD2000 drawing. Thanks in advance

[framedNlv]

I just ran across this thread and was wondering if I could get some information.







Thanks,
Chirs