Change Layer Color of selected layer in a Block or Xref

[omorah]

Currently I can use the Express Tool to freeze a layer in a block or an xref with the command "LAYFRZ". I was would like to be able to change the color of a selected layer in a block or xref to a specified color. I would like an automation since I always change some layers in an xref to color 59. Instead of checking what layer name it is by opening the layer or using the Express Tool function "LIST XREF / BLOCK PROPERTIRES", I would like to just pick the layer and have it change it's color to color 59 (or any color I chose to save with the lisp routine).

Would someone have a lisp that might be able to do this. I have been searching on the web on such lisp, but keep finding similar.
Thanks

I am using AutoCAD 2006 & Windows XP SP2

[rkmcswain]

The Layer Properties command in ToolPac can do it. I use this all the time.

[omorah]

Could someone please tell me where the function LAYFRZ lisp is located? It is an Express Tools function. Is this embedded into another grouped lisp? Thanks.

[framedNlv]

It is now part of acad and the toolbar is called "Layers II". It will be a little hard to get used to because autodesk decided to change the icons.


Chris

[T.Willey]

(defun c:ChangeLayerColor (/ Sel EntList DataList cnt Num ClrNum EntData)

(if (setq Sel (nentsel "\n Select object to change layers color: "))
 (progn
  (if (> (length Sel) 2)
   (setq EntList (cons (car Sel) (last Sel)))
   (setq EntList (cons (car Sel) EntList))
  )
  (setq DataList
   (mapcar
    '(lambda (x / EntData)
     (setq EntData (entget x))
     (cons (cdr (assoc 0 EntData)) (cdr (assoc 8 EntData)))
    )
    EntList
   )
  )
  (setq cnt 0)
  (textscr)
  (prompt "\n Select number of layer to change color: ")
  (foreach lst DataList
   (prompt (strcat "\n " (itoa cnt) " - " (cdr lst) " - Object [ " (car lst) " ]"))
   (setq cnt (1+ cnt))
  )
  (while
   (and
    (not (setq Num (getint (strcat "\n Select number between 0 - " (itoa (1- cnt)) ": "))))
    (not (< 0 Num (1- cnt)))
   )
  )
  (graphscr)
  (if (and Num (setq ClrNum (acad_colordlg 0)))
   (progn
    (setq EntData (entget (tblobjname "Layer" (cdr (nth Num DataList)))))
    (entmod
     (subst
      (cons 62 ClrNum)
      (assoc 62 EntData)
      EntData
     )
    )
    (command "_.Regen")
   )
  )
 )
)
(princ)
)

[omorah]

Thank You!
Thank You!
Thank You!

[T.Willey]

Thank You!
Thank You!
Thank You!

You're welcome.