To Scale & Center: VPORTS Refined

[CEHill]

Scaling and centering viewports of LARGE scale site plans seem very diffcult in AutoCAD Vanilla.

I have tried the various ZOOM flavors including CENTER & SCALE nXP.

Are there any available LISP routines (for AutoCAD 2004) that let the user set the viewport scale and define the viewport center?

NOTE: This functionality is available in a vertical (autodesk Mechanical) I use elsewhere - I am spoiled and need this for vanilla here.

[mpeterson79]

I'd be interested in this as well - the ability to set a scale, and then pick a point as the viewport center. All our viewports are circular, and awkard to align via other methods. Not impossible, but awkward.

[T.Willey]

Call while inside an active viewport.

(defun c:CSViewport (/ Sc Pt cViewport AcadObject)

        (vl-load-com)
	(setq AcadObject (vlax-get-Acad-Object))
	(setq Sc (getreal "\n Enter scale of viewport (where 48 would be 1/4\"): "))
	(setq Pt (getpoint "\n Select center point of viewport: "))
	(setq cViewport
		(vlax-ename->vla-object
			(ssname
				(ssget "x"
					(list
						(cons 0 "VIEWPORT")
						(cons 410 (getvar "ctab"))
						(cons 69 (getvar "cvport"))
					)
				)
				0
			)
		)
	)
	(vlax-invoke AcadObject 'ZoomCenter Pt 1.0)
	(vla-put-CustomScale cViewport (/ 1.0 Sc))
	(princ)
)

[CEHill]

All visiting here will thank you for that golden lisp code!

Thanks again "T"

[T.Willey]

You're welcome.