Convert Field to Text within Block Globally

[OCD]

I have an old block with FIELDs referencing a lookup value. My new block is just the attribute input...didn't like the FIELD look up. Is there a way to replace the old FIELD block with the new block, where the field value will carry over to the new block? The attributes are named the same, I just removed the field and lookup.

* - I have tried BLOCKREPLACE, but it won't replace block for some reason.
* - I tried the old fashion method of inserting the new block & running attsync, but field remains and upon regen or ATTSYNC "####" comes up since look up is missing.
* - I found a Lisp routine, REPL.LSP, that replaced the block, but left the field and regen/attsync issue remains as mentioned above.
* - Did find a program online that appears to do what I want, but i don't want to spend $ for it.

Basically I need a way to globally change field to text within a block. From there I should be able to replace the block. Any suggestions.

[OCD]

Anyone have a solution?

[irneb]

Try this LISP. Save it to a file with a LSP extension & load via Tools --> Load Application. Then type the command FLD2TXT at the command prompt. This will change all the attributes in the block to only text values - thus removing any fields.

;; Start copy here

(vl-load-com)
(defun c:FLD2TXT (/ ss n bn an ad s)
  (prompt
    "Select the blocks you wish to remove the field links from: "
  ) ;_ end of prompt
  (setq ss (ssget '((0 . "INSERT"))))	;Get selection set from user
  (setq n 0)				;Initialize counter
  ;; Step through selection set one entity at a time
  (while (< n (sslength ss))
    (setq bn (ssname ss n))		;Get the nth entity in the selection set
    (setq an (entnext bn))		;Get the next enity after bn
    ;; Step through each next entity until it is not an attribute
    (while (and	an			;Check if entity is found
		(setq ad (entget an))	;Get data
		(= "ATTRIB" (cdr (assoc 0 ad))) ;Check if attribute
	   ) ;_ end of and
      (setq s (cdr (assoc 1 ad)))	;Get text value
      (setq ad (subst (vl-list* 1 "") (assoc 1 ad) ad))
					;Clear the attribute's value
      (entmod ad)			;Modify the entity
      (setq ad (subst (vl-list* 1 s) (assoc 1 ad) ad))
					;Set the attribute's value back to only the text
      (entmod ad)			;Modify the entity
      (entupd an)			;Update screen to show change
      (setq an (entnext an))		;Get next entity
    ) ;_ end of while
    (setq n (1+ n))			;Increment counter
  ) ;_ end of while
  (setq ss nil)				;Clear selection set
  (gc)					;Clear unused memory
  (princ)
) ;_ end of defun

;; End copy here

[OCD]

Thank you...worked perfectly. Just don't ATTSYNC again, since this will make the field come back.

[Hammer.John.J]

Try this LISP. Save it to a file with a LSP extension & load via Tools --> Load Application. Then type the command FLD2TXT at the command prompt. This will change all the attributes in the block to only text values - thus removing any fields.

;; Start copy here

(vl-load-com)
(defun c:FLD2TXT (/ ss n bn an ad s)
  (prompt
    "Select the blocks you wish to remove the field links from: "
  ) ;_ end of prompt
  (setq ss (ssget '((0 . "INSERT"))))	;Get selection set from user
  (setq n 0)				;Initialize counter
  ;; Step through selection set one entity at a time
  (while (< n (sslength ss))
    (setq bn (ssname ss n))		;Get the nth entity in the selection set
    (setq an (entnext bn))		;Get the next enity after bn
    ;; Step through each next entity until it is not an attribute
    (while (and	an			;Check if entity is found
		(setq ad (entget an))	;Get data
		(= "ATTRIB" (cdr (assoc 0 ad))) ;Check if attribute
	   ) ;_ end of and
      (setq s (cdr (assoc 1 ad)))	;Get text value
      (setq ad (subst (vl-list* 1 "") (assoc 1 ad) ad))
					;Clear the attribute's value
      (entmod ad)			;Modify the entity
      (setq ad (subst (vl-list* 1 s) (assoc 1 ad) ad))
					;Set the attribute's value back to only the text
      (entmod ad)			;Modify the entity
      (entupd an)			;Update screen to show change
      (setq an (entnext an))		;Get next entity
    ) ;_ end of while
    (setq n (1+ n))			;Increment counter
  ) ;_ end of while
  (setq ss nil)				;Clear selection set
  (gc)					;Clear unused memory
  (princ)
) ;_ end of defun

;; End copy here

i need to do this for dimensions and mtext

[irneb]

Try this:

(vl-load-com)
(defun c:FLD2TXT (/ ss n bn an ad s)
  (prompt
    "Select the blocks you wish to remove the field links from: "
  ) ;_ end of prompt
  (setq ss (ssget '((0 . "INSERT,MTEXT,DIMENSION,TEXT"))))    ;Get selection set from user
  (setq n 0)                ;Initialize counter
  ;; Step through selection set one entity at a time
  (while (< n (sslength ss))
    (setq bn (ssname ss n))        ;Get the nth entity in the selection set
    (setq ad (entget bn))               ;Get the entity's data
    (cond
       ((= "INSERT" (cdr (assoc 0 ad))) ;Check if block
        (setq an (entnext bn))        ;Get the next enity after bn
        ;; Step through each next entity until it is not an attribute
        (while (and    an            ;Check if entity is found
            (setq ad (entget an))    ;Get data
            (= "ATTRIB" (cdr (assoc 0 ad))) ;Check if attribute
           ) ;_ end of and
          (setq s (cdr (assoc 1 ad)))    ;Get text value
          (setq ad (subst (vl-list* 1 "") (assoc 1 ad) ad))
                        ;Clear the attribute's value
          (entmod ad)            ;Modify the entity
          (setq ad (subst (vl-list* 1 s) (assoc 1 ad) ad))
                        ;Set the attribute's value back to only the text
          (entmod ad)            ;Modify the entity
          (entupd an)            ;Update screen to show change
          (setq an (entnext an))        ;Get next entity
        ) ;_ end of while
      )
      (t
        (setq s (cdr (assoc 1 ad)))    ;Get text value
        (setq ad (subst (vl-list* 1 "") (assoc 1 ad) ad))
        (entmod ad)            ;Modify the entity
        (setq ad (subst (vl-list* 1 s) (assoc 1 ad) ad))
         (entmod ad)            ;Modify the entity
        (entupd an)            ;Update screen to show change
       )
    )
    (setq n (1+ n))            ;Increment counter
  ) ;_ end of while
  (setq ss nil)                ;Clear selection set
  (gc)                    ;Clear unused memory
  (princ)
) ;_ end of defun

[RickyD302]

I was able to get it to work but now after an AutoCAD restart I get

error: bad argument type: lentityp nil

Autocad 20111 64 bit, windows 7 pro

Also will this convert mleader fields to text?

[irneb]

Not yet, no. But also I'd avoid using this thing on annotative text. It needs a bit of rewriting to not screw up anno text's height. I'll get back with a fixed version ASAP.

[RickyD302]

That would be great.....I use it all annotative, multileaders and fields but I found not everyone does nor do they understand it so....I want to take the drawings and "dumb" them down My plan is do this on a copy and keep the intelligent drawing for me

[irneb]

Here goes:

(vl-load-com)
(defun c:FLD2TXT (/ ss n bn an ad s)
  (prompt
    "Select the objects you wish to remove the field links from: "
  ) ;_ end of prompt
  (setq ss (ssget '((0 . "INSERT,MTEXT,DIMENSION,TEXT,MULTILEADER")))) ;Get selection set from user
  (setq n 0) ;Initialize counter
  ;; Step through selection set one entity at a time
  (while (< n (sslength ss))
    (setq bn (ssname ss n)) ;Get the nth entity in the selection set
    (setq ad (entget bn)) ;Get the entity's data
    (cond
      ((= "INSERT" (cdr (assoc 0 ad))) ;Check if block
       (setq an (entnext bn)) ;Get the next enity after bn
       ;; Step through each next entity until it is not an attribute
       (while (and an ;Check if entity is found
                   (setq ad (entget an)) ;Get data
                   (= "ATTRIB" (cdr (assoc 0 ad))) ;Check if attribute
              ) ;_ end of and
         (setq s (cdr (assoc 1 ad))) ;Get text value
         (entmod (list (assoc -1 ad) (cons 1 ""))) ;Modify the entity
         (entmod (list (assoc -1 ad) (cons 1 s))) ;Modify the entity
         (entupd an) ;Update screen to show change
         (setq an (entnext an)) ;Get next entity
       ) ;_ end of while
      )
      ((= "MULTILEADER" (cdr (assoc 0 ad))) ;Check if block
       (setq ad (vlax-ename->vla-object bn)
             s (vla-get-TextString ad)
             )
       (vla-put-TextString ad "")
       (vla-put-TextString ad s)
      )
      ;; Anything else
      (t
       (setq s (cdr (assoc 1 ad))) ;Get text value
       (entmod (list (assoc -1 ad) (cons 1 ""))) ;Modify the entity
       (entmod (list (assoc -1 ad) (cons 1 s))) ;Modify the entity
       (entupd an) ;Update screen to show change
      )
    )
    (setq n (1+ n)) ;Increment counter
  ) ;_ end of while
  (setq ss nil) ;Clear selection set
  (gc) ;Clear unused memory
  (princ)
) ;_ end of defun

It should now also work for Multileaders and Annotative Text.