Numéroter l'ordre des présentations avec AUTOLISP

[jl.bajard]

Bonjour, Dans mon petit cartouche qui est inséré sur chaque folio de présentation, mon client me demande de rajouter une numérotation simple de 1 à .... qui suit l'ordre logique des présentations. j'ai créé un attribut pour cette information dans mon cartouche.
J'arrive à retrouver facilement le NOM associé à la présentation (code dxf "410" ou bien utiliser la commande "layoutlist") mais je ne sais pas comment trouver automatiquement son numéro logique de position (1, 2, 3...) pour pouvoir facilement trier les feuillets une fois imprimés sur papier.
Y a t il un code DXF pour le retrouver une méthode ?
Merci

[dom06]

je ne suis pas sur d'avoir compris la question
mais si tu veux sortir dans l'ordre les feuilles
il faut numeroter les onglets par ordre de sorti voulu.

[_gile]

Salut,

La fonction layoutlist ne retourne pas les présentations dans l'ordre
C'est le code de groupe DXF 71 des objets LAYOUT qui indique la position de chaque présentation (Model étant toujours 0)
On accède aux objets LAYOUT par le dictionnaire ACAD_LAYOUT

;; TabOrder
;; Retourne le numéro d'ordre de la présentation
;;
;; Argument : le nom de la présentation (chaîne)
;;
;; Retour : le numéro d'ordre de la présentation (entier)

(defun TabOrder (name / dict lay)
  (setq dict (dictsearch (namedobjdict) "ACAD_LAYOUT"))
  (if (setq lay (cdr (assoc 350 (member (cons 3 name) dict))))
    (cdr (assoc 71 (entget lay)))
  )
)

ou encore, en vlisp

(vla-get-TabOrder
  (vla-item
    (vla-get-Layouts
      (vla-get-ActiveDocument
	(vlax-get-acad-object)
      )
    )
    "Nom_présentation" 
  )
)