How to create a routine to batch process files or a directory

[Ed Jobe]

Put the lisp in a *.scr file and use ScriptPro to run it on any file/files you want. No programming necessary.

[Ed Jobe]

BTW, ScriptPro is open source now, on GitHub.
https://github.com/ADN-DevTech/Scrip...art-of-content

[Bruno.Valsecchi]

Or an another way with lisp.
In a new drawing copy-paste the code below directely in command line and execute the command MAKE_SCRIPT
Select a drawing in directory (any of them) to determine the folder to apply the script.
At the end, use command SCRIPT and select the "treat_folder.scr" generated by the lisp

(defun c:make_script ( / prefix file_scr)
  (setq
    prefix (strcat (vl-filename-directory (getfiled "Select a drawing file as WITNESS in a directory" "" "dwg" 16)) "\\")
    file_scr (open (strcat prefix "treat_folder.scr") "w")
  )
  (foreach dwg (vl-directory-files prefix "*.dwg" 1)
    (write-line "_.open" file_scr)
    (write-line (strcat "\"" prefix dwg "\"") file_scr)
;;
;;start of customizable party
;;
(write-line "((lambda ( / )" file_scr)
(write-line "(foreach lay '(\"G-ANNO-TEXT\" \"M-HVAC-DUCT-IDEN\" \"M-HVAC-CDFF-IDEN\" \"A-ANNO-NOTE\" \"A-DETL\" \"G-ANNO-REVC-IDEN\" \"A-ANNO-MATC\")" file_scr)
(write-line "(if (tblobjname \"layer\" lay)" file_scr)
(write-line "(command \"_.-laydel\" \"_N\" lay \"\" \"_Y\")" file_scr)
(write-line ")" file_scr)
(write-line ")" file_scr)
(write-line "))" file_scr)
;;
;;end of customizable party
;;
    (write-line "_.qsave" file_scr)
    (write-line "_.close" file_scr)
  )
  (close file_scr)
  (princ (strcat "\You can start SCRIPT :" prefix "treat_folder.scr"))
  (prin1)
)

I don't test it, I hope that I not have error syntax

[BlackBox]

Running Scripts within AutoCAD will process the drawings in series (one at a time).

Core Console allows for processing drawings both in series and parallel (multiple at once).

Here's a quick example that uses DOSLib to select multiple drawings for Core Console to process in parallel, just be mindful of how many drawings you choose to process at once, based on your workstation's CPU & RAM limitations:

First take at replacing BSU.

Here's the core LISP routine, which uses DOSLib to prompt for multiple drawing + .SCR (script) selection:

** Be sure to replace the text in red as needed **

(vl-load-com)

(defun c:SCRM() (c:ScriptMultiple))
(defun c:ScriptMultiple (/ app flag dwgs dwgPath script cprofile)
;;;
;;;  AcCoreConsole.exe [/i <input dwg>] /s <script>[/product <product>] [/l <language>]
;;;  [/isolate <userid> <userDataFolder>] [/readonly] [/p[rofile] <profile>] 
;;;
  (if
    (and
      (setq app (findfile "accoreconsole.exe"))
      (setq flag (dos_version))
      (setq dwgs
             (dos_getfilem
               "Select drawing(s) to process:"
               (if *Dwg_LastPath*
                 *Dwg_LastPath*
                 (getvar 'dwgprefix)
               )
               "Drawing files (*.dwg)|*.dwg||"
             )
      )
      (setq *Dwg_LastPath* (car dwgs))
      (setq dwgPath *Dwg_LastPath*)
      (setq dwgs (cdr dwgs))
      (setq script
             (dos_getfiled
               "Select a Script to run:"
               (if *Script_LastPath*
                 *Script_LastPath*
                 "C:\\ProgramData\\Autodesk\\C3D 2019\\BatchSaveTool\\Scripts"
               )
               "Script (*.scr)|*.scr||"
             )
      )
      (setq *Script_LastPath* (vl-filename-directory script))
      (setq cprofile (getvar 'cprofile))
    )
     (progn
       (foreach dwg dwgs
         (startapp
           (strcat
             "\""
             app
             "\" /i \""
             dwgPath
             dwg
             "\" /s \""
             script
             "\" /product \"C3D\" /p \""
             cprofile
             "\""
           )
         )
       )
     )
     (cond
       (dwgs (prompt "\n** No script selected ** \n"))
       (flag (prompt "\n** No drawing(s) selected ** \n"))
       (app (prompt "\n** DOSLib required ** \n"))
       ((prompt
          "\n** Unable to find \"AcCoreConsole.exe\" in support paths ** \n"
        )
       )
     )
  )
  (princ)
)

Cheers

[aaronic_abacus]

Create-a-list-of-drawings-and-write-them-to-a-text-file

http://forums.augi.com/showthread.ph...hlight=lookdbd