Check for no viewports in paperspace?

[framedNlv]

Using lisp how do I check for NO viewports in paperspace.


(if ( ? )
(progn
( work )
)
)

[BlackBox]

This may help:

(foreach lay  (layoutlist)
  (if (and (setq ss
                  (ssget "_x"
                         (list '(0 . "VIEWPORT") (cons 410 lay))))
           (< 1 (setq i (sslength ss))))                                ; <-- Ignore pviewport
    (prompt (strcat "\nFound "
                    (rtos (1- i) 2 0)
                    " on tab \""
                    lay
                    "\""))
    (prompt (strcat "\n** No viewports found on tab \"" lay "\" ** "))))

[framedNlv]

Thanks,
I didn't want to check all tabs but the current so I started messing with what you wrote.

  (if (and (setq ss
                  (ssget "_x"
                         (list '(0 . "VIEWPORT") (cons 410 (getvar "ctab")))));changed to ctab
           (= 1 (setq i (sslength ss))))                                ; <-- Ignore pviewport  ;;changed to = 1
    
    (alert "none");my work here
   )

I guessing it was reading the paperspace viewport as one so I changed it to say "=" for the sslength and removed the for each.

These are on old R14 drawings and only have one viewport.

Somehow I was trying to use the not or nil and couldn't get anything to work.


Thanks again.

Chris

[BlackBox]

Thanks,
I didn't want to check all tabs but the current so I started messing with what you wrote.

  (if (and (setq ss
                  (ssget "_x"
                         (list '(0 . "VIEWPORT") (cons 410 (getvar "ctab")))));changed to ctab
           (= 1 (setq i (sslength ss))))                                ; <-- Ignore pviewport  ;;changed to = 1
 
    (alert "none");my work here
   )

I guessing it was reading the paperspace viewport as one so I changed it to say "=" for the sslength and removed the for each.

These are on old R14 drawings and only have one viewport.

Somehow I was trying to use the not or nil and couldn't get anything to work.


Thanks again.

Chris

Here's another (shorter) example:

(if
  (not
    (setq ss
           (ssget "_x"
                  (list '(0 . "VIEWPORT")
                        (cons 410 (getvar 'ctab))
                        '(-4 . "<NOT")
                        '(69 . 1)                                ; <-- Ignore pviewport 
                        '(-4 . "NOT>")
                        )
                  )
          )
    )
  ;; <-- Your code here
  )

[alanjt]

BlackBox_, just for academic purposes, you should know that it's highly inefficient to create multiple calls to ssget when you could just make one, step through the selection and manipulate lists.

[BlackBox]

Using lisp how do I check for NO viewports in paperspace.

(if
  (not
    (setq ss
           (ssget "_x"
                  (list '(0 . "VIEWPORT")
                        (cons 410 (getvar 'ctab))
                        '(-4 . "<NOT")
                        '(69 . 1)                                ; <-- Ignore pviewport 
                        '(-4 . "NOT>")
                        )
                  )
          )
    )
  ;; <-- Your code here
  )

Mat, just for academic purposes, you should know that it's highly inefficient to create multiple calls to ssget when you could just make one, step through the selection and manipulate lists.

What are you talking about???

Maybe it's because I'm home, sitting on my couch after a kick-@$$ meal, but what about the code I posted is ineffective, or falls short of the OP's request?

To clarify, neither of the posts of code that I've made in this thread make more than a single selection set, and I have done no list/selection set manipulation... I'm simply checking for paper space viewports (other than the PViewport itself).

[alanjt]

What are you talking about???

Maybe it's because I'm home, sitting on my couch after a kick-@$$ meal, but what about the code I posted is ineffective, or falls short of the OP's request?

To clarify, neither of the posts of code that I've made in this thread make more than a single selection set, and I have done no list/selection set manipulation... I'm simply checking for paper space viewports (other than the PViewport itself).

I was referring to your first post (#2). You foreach through the return from (layoutlist) and make a ssget selection for each return layout.

[BlackBox]

I was referring to your first post (#2). You foreach through the return from (layoutlist) and make a ssget selection for each return layout.

Thanks for the clarification, Alan. I wasn't tracking the foreach preceding the ssget call (making the multiple calls you mentioned) before I replied.

Only after that post did I find out the OP only wanted to query a single layout.

Point taken.

[hofcad]

Using lisp how do I check for NO viewports in paperspace.


(if ( ? )
(progn
( work )
)
)

I found that the ssget method is not working well, when the viewports
are not fully zoomed out.
Therefore:

(defun c:DelLayouts (/ ~Tm LayoutsLst i Layout)
(Setq ~Tm (getvar "TILEMODE"))
  (setvar "TILEMODE" 1)
  (setq LayoutsLst (layoutlist))
  (setq i 0)
  (repeat (length LayoutsLst)
    (command "_.LAYOUT" "_S" (nth i LayoutsLst))
    (command "_.PSPACE")
    (command "_.ZOOM" "_E")
    (setq i (1+ i))
  )
  (setq i 0)
  (repeat (length LayoutsLst)
    (setq Layout (nth i LayoutsLst))
    (if	(< (SSlength
	    (ssget "_X" (list '(0 . "VIEWPORT") (cons 410 Layout)))
	  )
	  2
	)
      (command "_.LAYOUT" "_D" Layout);The work is: to Delete Layout with no Viewports
    )
    (setq i (1+ i))
  )
  ;(setvar "TILEMODE" ~Tm)
  (princ)
)

or better

(defun c:DelLayouts(/ doc ent Oke HasVp)
  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object)))
  (vlax-for lay	(vla-get-layouts doc)
    (setq HasVp nil
	  Oke nil
    )
    (vlax-for ent (vla-get-block lay)
      (if (and Oke
	       (eq (vla-get-objectname ent) "AcDbViewport")
	  )
	(setq HasVp T)
	(setq Oke T)
      )
    )
    (and (not HasVp)
	 (if (not (eq "MODEL" (strcase (vla-get-Name lay))))
	   (vla-delete lay);The work is: to Delete Layout with no Viewports
	 )
    )
  )
)

Regards, HofCAD CSI.

[peter]

Here is a routine that creates a list of sublists with the assoc string being the layout name and subsequent viewport objects for each layout following.

Remember the first viewport in each layout (except model) is the layout itself.

Peter

(defun C:ViewportList (/
                       lstOfSublists
                       lstSublist
                       objItem
                       objLayout
                      )
 (vlax-for objLayout (vla-get-layouts 
                      (vla-get-activedocument 
                       (vlax-get-acad-object)))
  (setq lstSublist (list (vla-get-name objLayout)))
  (vlax-for objItem (vla-get-block objLayout)
   (if (= (vla-get-objectname objItem) "AcDbViewport")
    (setq lstSublist (cons objItem lstSublist))
   )
  )
  (setq lstOfSublists (cons (reverse lstSublist) lstOfSublists))
 )
 (reverse lstOfSublists)
)