Using "-insert" with attributes in a loop

[jmcshane]

Hi,

Could anybody help me get this to work? (without laughing if its blatantly obvious)

(while 
   (vl-cmdf "-INSERT" (vla-get-name  BlkObj) PAUSE "1" "1" PAUSE)
    (if (<= TxtNum 9)
	(setq BlkTxt (strcat TxtPre "0" (itoa TxtNum)))
	(setq BlkTxt (strcat TxtPre (itoa TxtNum)))
      )
    (setq NewBlkObj (vlax-ename->vla-object (entlast)))
      (vla-put-textstring
	(nth 0
	     (vlax-safearray->list
	       (variant-value
		 (vla-getattributes NewBlkObj)
	       )
	     )
	)
	BlkTxt
      )
 (setq TxtNum (1+ TxtNum))
    )

Thanks in advance

[ccowgill]

Hi,

Could anybody help me get this to work? (without laughing if its blatantly obvious)

(while 
   (vl-cmdf "-INSERT" (vla-get-name  BlkObj) PAUSE "1" "1" PAUSE)
    (if (<= TxtNum 9)
    (setq BlkTxt (strcat TxtPre "0" (itoa TxtNum)))
    (setq BlkTxt (strcat TxtPre (itoa TxtNum)))
      )
    (setq NewBlkObj (vlax-ename->vla-object (entlast)))
      (vla-put-textstring
    (nth 0
         (vlax-safearray->list
           (variant-value
         (vla-getattributes NewBlkObj)
           )
         )
    )
    BlkTxt
      )
 (setq TxtNum (1+ TxtNum))
    )

Thanks in advance

probably not without some more information. What is it supposed to do? There appear to be some variables that are not defined in your segment of code, their meaning would be important to getting the function to work properly

[irneb]

A trick I usually use to check if a command has completed is to check the CMDACTIVE and / or CMDNAMES sysvars. This way you could know that -INSERT is still asking for data (if you have ATTREQ=1) without knowing how many ATTRIBS are in the block.this is if you still want to use the (command ...) interface.

If you want to do the same thing as your code, but not use the vla extensions the normal entlast, entnext, entget & entmod after the -INSERT does the same thing as the vla functions you're using without the back-and-forth between LISP and ActiveX.

Something like:

(setq atdata (entget (entnext (entlast))))
(setq atdata (subst (cons 1 BlkTxt) (assoc 1 atdata) atdata))
(entmod atdata)
(entupd (entlast))

[jmcshane]

The big picture is that I am trying copy a block with a single attribute and have the attribute increase by 1 every time I copy it.

What I can't seem to do is end the loop.

;Get user to enter Prefix if there is one. eg TP
;Get user to enter the first number in the sequence
;If the first number is between 1 and 9, stick a 0 in front of it.
;Select the block with the attribute
;Check that it has an attribute
;And then, keep copying the block and increasing the attribute by 1.

I was using the vla-copy and vla-move which did work but the problem was that I could not see the block in relation to the previous one untill after it was placed.

(defun c:Copya ()
  (vl-load-com)
  (setq	AcadObject (vlax-get-Acad-Object)
	ActiveDoc  (vla-get-ActiveDocument AcadObject)
	util	   (vla-get-utility ActiveDoc)
  )

  (setvar "ATTREQ" 0)
  
  (setq	TxtPre (strcase (getstring "\nEnter Prefix :"))
	TxtNum (getint "\nEnter First number :")
  )
  (if (<= TxtNum 9)
    (setq BlkTxt (strcat TxtPre "0" (itoa TxtNum)))
    (setq BlkTxt (strcat TxtPre (itoa TxtNum)))
  )

  (setq	BlkObj	 (vlax-ename->vla-object
		   (car (entsel "\nPlease Select a Block to copy :"))
		 )
	InsPoint (vla-get-insertionpoint BlkObj)
  )

  (if (= (vla-get-hasattributes BlkObj) :vlax-true)
    (vla-put-textstring
      (nth 0
	   (vlax-safearray->list
	     (variant-value
	       (vla-getattributes BlkObj)
	     )
	   )
      )
      BlkTxt
    )
    (alert "Selected Block Does Not Have Any Attributes !")
  )

  (while
   (vl-cmdf "-INSERT" (vla-get-name  BlkObj) pause "1" "1" pause)
    (setq TxtNum (1+ TxtNum))
    (if (<= TxtNum 9)
	(setq BlkTxt (strcat TxtPre "0" (itoa TxtNum)))
	(setq BlkTxt (strcat TxtPre (itoa TxtNum)))
      )
    (setq NewBlkObj (vlax-ename->vla-object (entlast)))
      (vla-put-textstring
	(nth 0
	     (vlax-safearray->list
	       (variant-value
		 (vla-getattributes NewBlkObj)
	       )
	     )
	)
	BlkTxt
      )
    
    )
(setvar "ATTREQ" 1)
)

[irneb]

In this case you could use this, it doesn't exactly do what you wanted. But, it does increment pic picking text / attributes and allows for a minimum number of digits (i.e. 001, 002, ...., 009, 010, 011, ... , 099, 100, 101, ...). Maybe you could use the code to implement your utility.

[jmcshane]

In this case you could use this

That is a very neat trick. It'll take me a week to study all of that!


I think my main problem is just getting the loop to work though.

Many Thanks


John

[irneb]

I didn't really mean it like that ... you could use this after copying the blocks.

If you simply want to have the loop stop if the user doesn't specify a point, then you need to obtain that point 1st, not during the actual command call. Something like:

;; Replace your (while (vl-cmdf ...) with this
(setq ang 0.0)
(while (and ang (setq pt (getpoint "Pick insertion point: ")))
  (if (setq ang (getangle pt (strcat "Pick rotation <" (rtos ang) ">: ")))
    (progn
      (setq ang (* 180.0 (/ pi ang))) ;Convert Radians to Degrees
      (vl-cmdf "-INSERT" (vla-get-name  BlkObj) pt "1" "1" ang)
      ;; Continue the rest of your code inside the while
    )
  )
)

Now if the user stops selecting a point, the pt is SETQed ti nil so the loop stops. And if the user doesn't specify an angle the loop also stops.

[irneb]

Sorry, I screwed up a bit, my radians to degrees convert was wrong. And after some thought I noticed that if the user doesn't specify an angle - the default should be used . So here's the correct one:

(setq ang 0.0)
(while (setq pt (getpoint "Pick insertion point: "))
  (if (setq ang1 (getangle pt (strcat "Pick rotation <" (rtos ang) ">: ")))
    (setq ang (* 180.0 (/ ang1 pi)))
  ) ;_ if
  (vl-cmdf "-INSERT" (vla-get-name BlkObj) pt "1" "1" ang)
  ;; Continue the rest of your code inside the while
) ;_ while

[jmcshane]

Thanks irneb,

Yes that does work fine, but I really need to see the block in relation to the previous one before I pick the insertion point.

The particular point I have for this routine is I might have a sewer line that goes on for a few miles in any direction and I need to break it down into individual sheets. And with that code that you gave me, and the code I had myself using the vla-copy and vla-move, I don't actually get to see the block untill after it has been inserted. So, while inserting the block representing the sheet,it might not actually overlap the previous one. I won't know untill after it has been inserted.

Thanks for your time and patience.

John

[irneb]

Try this:

(while (or (command "-INSERT" (vla-get-name  BlkObj) (setq pt (getpoint)) "1" "1" pause) pt)
  (if pt
    (progn
      ;; Your code
    )
  )
)

Used the (command function instead of the vl-cmdf, so the command executes as and when you ask for the point, not after you've already gotten the point. I think this is what you wanted.