move after insert problem

[dgomez.189897]

Hi,

I have this piece of code in my routine which inserts a block from another dwg into the one I run the LISP from.

The code works in the sense that it does insert the block and moves it, but it is not moving it the displacement I am giving in the code always. Sometimes it inserts and moves the first block right but then the second is moved a constant displacement.

Sometimes it inserts both at the same constant displacement....

Does anybody know what is wrong with the code...or if it's the code or how to solve this?

(command "_insert" pipe_dir_top_last pti "1" "1" "0")
(if (/= top_last_verif+1 nil) (command "move" "l" "" "d" "0,0,250"))
(if (/= top_last_verif+2 nil) (command "move" "l" "" "d" "0,0,500"))
(if (/= top_last_verif-1 nil) (command "move" "l" "" "d" "0,0,-250"))
(if (/= top_last_verif-2 nil) (command "move" "l" "" "d" "0,0,-500"))
(command "_insert" pipe_dir_top pti "1" "1" "0")
(if (/= top_verif+1 nil) (command "move" "l" "" "d" "0,0,250"))
(if (/= top_verif+2 nil) (command "move" "l" "" "d" "0,0,500"))
(if (/= top_verif-1 nil) (command "move" "l" "" "d" "0,0,-250"))
(if (/= top_verif-2 nil) (command "move" "l" "" "d" "0,0,-500"))

thanks!,
dario

[RobertB]

You've made the common mistake of not considering running OSnaps. Use the None OSnap override every time you are providing a point in a (command) function.

(I also cleaned up the nonsensical if test (not equal to nil is the same as the variable has data) and wrapped it into a (cond) statement.)

Example:

(command "_insert" pipe_dir_top_last "_non" pti "1" "1" "0")
(command "move" "l" "" "d" "_non")
(cond 
 (top_last_verif+1 (command "0,0,250"))
 (top_last_verif+2 (command "0,0,500"))
 (top_last_verif-1 (command "0,0,-250"))
 (T (command "0,0,-500")))
(command "_insert" pipe_dir_top "_non" pti "1" "1" "0")
(command "move" "l" "" "d" "_non")
(cond
 (top_verif+1 (command "0,0,250"))
 (top_verif+2 (command "0,0,500"))
 (top_verif-1 (command "0,0,-250"))
 (T (command "0,0,-500")))

[irneb]

Or change OSMODE to 0 after saving the old value to a variable, then set it back once you're done, e.g.

(setq OldSnap (getvar "OSMODE"))
;; Continue your code here
(setvar "OSMODE" OldSnap)

[RobertB]

Or change OSMODE to 0 after saving the old value to a variable, then set it back once you're done...

Except that if you are also allowing the user to pick points somewhere in that process, you hosed the user's favorite running OSnaps. Which would lead to unhappy users. I know I would be unhappy.

[irneb]

Except that if you are also allowing the user to pick points somewhere in that process, you hosed the user's favorite running OSnaps. Which would lead to unhappy users. I know I would be unhappy.

Yes you're perfectly correct. My suggestion's what you do when you're a lazy programmer ... like me. Yours is definitely a better solution!

[dgomez.189897]

Thanks much Robert,

I got this routine at work and I am modifying it without previous experience with LISP. I hadn't even figured out how conditional loops worked in LISP (I've work with "IF/ELSE")

I used your code. Had to modify it a little because the way I had it, the "T" (or "ELSE") was just passing the "IF"s I had.

Now it seems that is working in a more controlled way but it is moving the blocks (although some constantly (2000,2000,0) ) in X & Y coord. and the code is moving them in Z coord.??

Because of the way the routine is, it inserts some blocks more than once and it is moving them different displacements..??

If you have any idea why this could be, I'll appreciate it. Meanwhile, I'll be hitting myself with it...

The code looks like this now:

(command "_insert" pipe_dir_top_last "_non" pti "1" "1" "0")
(command "move" "l" "" "d" "_non")
(cond
(top_last_verif_0 (command "0,0,0"))
(top_last_verif+1 (command "0,0,250"))
(top_last_verif+2 (command "0,0,500"))
(top_last_verif-1 (command "0,0,-250"))
(T (command "0,0,-500")))
(command "_insert" pipe_dir_top "_non" pti "1" "1" "0")
(command "move" "l" "" "d" "_non")
(cond
(top_verif_0 (command "0,0,0"))
(top_verif+1 (command "0,0,250"))
(top_verif+2 (command "0,0,500"))
(top_verif-1 (command "0,0,-250"))
(T (command "0,0,-500")))

[dgomez.189897]

and thanks irneb, I'd have done that like that too.. I didn't know you could do it the way Robert did.

and yes, I'd be unhappy with the osnaps had i done it that way

[dgomez.189897]

and I just figured out that it is only when it reads the move (0,0,0) that it goes crazy.

it seems that it is only having problems when the conditional is true for "top_verify_0" or "top_last_verify_0"...

[dgomez.189897]

Thanks all!!

got it working now!

[RobertB]

and I just figured out that it is only when it reads the move (0,0,0) that it goes crazy.

it seems that it is only having problems when the conditional is true for "top_verify_0" or "top_last_verify_0"...

Well, in all actuality, even having that condition is useless. Why even bother with the move if you are displacing by 0,0,0?

(command "_insert" pipe_dir_top_last "_non" pti "1" "1" "0")
(cond 
 (top_last_verif_) ; if set, do not move
 (T
  (command "move" "l" "" "d" "_non")
  (cond   
   (top_last_verif+1 (command "0,0,250"))
   (top_last_verif+2 (command "0,0,500"))
   (top_last_verif-1 (command "0,0,-250"))
   (T (command "0,0,-500")))))
(command "_insert" pipe_dir_top "_non" pti "1" "1" "0")
(cond 
 (top_verif_0) ; if set, do not move
 (T
  (command "move" "l" "" "d" "_non")
  (cond
   (top_verif+1 (command "0,0,250"))
   (top_verif+2 (command "0,0,500"))
   (top_verif-1 (command "0,0,-250"))
   (T (command "0,0,-500")))))