Crash is gone; Next problem

[dwbrink]

I am looking for a clean method for a program to find how many decimal places a dimension has so I can write it correctly to a txt file. I am using assoc 42 with ssget function to extract the dimension.
I could turn it into a string an walk through it with a counter, but I am hoping there is a much cleaner method.

This is the same code I posted yesterday under "Crash using a "while" statement" with corrections.

(defun c:BB ()

(Setvar "osmode" 0)
(setq INFOLST nil)
(setq T1 1)
(setq SS 1)

(while (/= SS nil)

    (Prompt "Pick Dimension")
    (setq SS (ssget))
        (if (/= SS nil)
            (progn
                (setq ELST (entget(ssname SS 0))
                      P1 (cdr(assoc 11 ELST))
                      P2 (list (+ (car P1) 0.55)(+ (cadr P1) 0.38) 0.0)
                      P3 (list (- (car P2) 0.10)(- (cadr P2) 0.10) 0.0)
                )
                (command "circle" P2 0.25 "")
    
                (setq T2 (itoa T1))
                (command "text" P3 "0.180" "0" T2)

                (setq D1 (cdr(assoc 42 ELST))
                      D1 (rtos D1 2 3)
                      INFOLST (append INFOLST (list D1))
                      T1 (1+ T1)
                )

            );end progn
        );end if
);end while

;Write INFOLST out to file

 (setq R (length INFOLST)
       FN "c:\\cad\\Iso9000.txt"
       I 0
      TEX (open FN "w")
 )
      (repeat R
          (setq L (nth I INFOLST))
          (write-line L TEX)
          (setq I (1+ I))
      )
(close TEX)

(princ)
)
(princ)

Moderator Note:

Please use [ CODE ] tags...

[paula.romano]

dwbrink,

Why can't you just use string length?

Paula

[dwbrink]

Paula

You are partially there. I can parse the string until I find the decimal point,remove what is left of the point plus the point and than do a string length on what is remaining. What I was hoping for was a single function to avoid the parsing process.
Thanks anyway!

David

[aaronic_abacus]

(SETQ rv (ATOF strv));coverts a string to a real
(SETQ nstrv (RTOS rv 2 0));converts a real to a string reflecting percision

[kennet.sjoberg]

. . .I could turn it into a string an walk through it with a counter, but I am hoping there is a much cleaner method. . . .

That is wery tricky because (rtos real 2 n ) will give you different numbers of decimals, even with trailing zeros.

Try (getvar "DIMDEC" )

: ) Happy Computing !

kennet

[aaronic_abacus]

Opps, I guess RTOS rounds the real up(from .5) when applying precision

[T.Willey]

See if this gets you what you want. If not, then it should get you going on the right track.

(defun c:Test (/ Sel EntData BlkEnt Str Pos)
    
    (if
        (and
            (setq Sel (entsel "\n Select dimension: "))
            (= (cdr (assoc 0 (setq EntData (entget (car Sel))))) "DIMENSION")
            (setq BlkEnt (tblobjname "block" (cdr (assoc 2 EntData))))
        )
        (while (setq BlkEnt (entnext BlkEnt))
            (if (= (cdr (assoc 0 (setq EntData (entget BlkEnt)))) "MTEXT")
                (progn
                    (setq Str (cdr (assoc 1 EntData)))
                    (if (setq Pos (vl-string-search ";" Str))
                        (setq Str (substr Str (+ 2 Pos)))
                    )
                )
            )
        )
    )
    Str
)

[dwbrink]

Tim Willey

This does get the "dimension" value reflecting (dimdec) and not (luprec) which was my problem using (assoc 42). Thank you for that, but I am not sure what you are doing. It would be greatly appreciated if you could make this code more linear or add some comments.
Thanks again for the direction.
David

[T.Willey]

David,

I think it is pretty simple once you understand how Acad stores the dimension information. The dimension is a block, and all the lines and texts are entities within that and get updated per the dim style, so with that said I'll break it down a little for you.

The first set of statements ( within the and ):
Select an entity.
Check to make sure it is a dimension.
Get the ename of the block that defines the selected dimension.

The next step is the while statement with a call to entnext. I use this since a block definition is a collection of entities. So the next entity after we get the block definition block, which is a place holder to say where the block starts, is the first entity that makes up the block. We don't know the order the block is made, but we do know that we shouldn't have more than one mtext entity, so we are just checking each entity to see if it is the mtext entity, which is what is shown in the drawing. Once we know we have a mtext entity, then we just grab the value of it. I noticed that it had a formation code when I tested this on a simple drawing, that is why we check the string value for ';'. If it has that, then return what is after it, as that is what is really shown as the dimension value.

Hope that makes sense. You're welcome.

[dwbrink]

Tim Willey

Yes! that makes perfect sence and I learned some things I did not know.
Thankyou again.

David