Creating a Invert Level LISP

[Zuke]

Hey Guys,

Hopefully someone can help, this is a large complicated lisp that I would love created, but i have no idea how to do it.

What I need is, a routine that will allow me to select a polyline, enter a start invert level (in meters) and a gradent (0.0166666).
Then it will add at each endpoint/vertex a text entry with the a number based on the Start Level - (the distance from the start of the polyline to the endpoint/vertex multiplyed by the gradient).

I have attached an example of what i need.

Any help will be greatly appreciated.

[aaronic_abacus]

AutoCAD Land Development Desktop has "PIPE" routines to automate this design process.

[Zuke]

Are there any straight Autocad routins as i doubt my boss will want another CAD package in the office..

[kennet.sjoberg]

You can start to play with this code

(defun c:test ( / StartLevel Gradient Poly Vl-Obj #Vertex Index Dist Level Point )
  (setq StartLevel 123.45 )
  (setq Gradient 0.0166666 )
  (setq Poly (entsel "Please choose the polyline : " ) )
  (vl-load-com)
  (setq Vl-Obj (vlax-ename->vla-object (car Poly )) )
  (setq #Vertex (fix (vlax-curve-getEndParam Vl-Obj )) )
  (setq Index -1 )
  (repeat (1+ #Vertex )
    (setq Index (1+ Index ) )
    (setq Dist (vlax-curve-getDistAtParam Vl-Obj Index ) )
    (setq Level (rtos (+ StartLevel (* Gradient Dist )) 2 3 ) )
    (setq Point (vlax-curve-getPointAtParam Vl-Obj Index ) )
    (command "._text" "J" "MC" Point "10" "0" Level )
  )
  (princ)
)

: ) Happy Computing !

kennet

[Zuke]

Thanks so much! I tweaked it a bit to suit what i need. I learnt alot from this lisp routine and how they work.

[Zuke]

You can start to play with this code

(defun c:test ( / StartLevel Gradient Poly Vl-Obj #Vertex Index Dist Level Point )
  (setq StartLevel 123.45 )
  (setq Gradient 0.0166666 )
  (setq Poly (entsel "Please choose the polyline : " ) )
  (vl-load-com)
  (setq Vl-Obj (vlax-ename->vla-object (car Poly )) )
  (setq #Vertex (fix (vlax-curve-getEndParam Vl-Obj )) )
  (setq Index -1 )
  (repeat (1+ #Vertex )
    (setq Index (1+ Index ) )
    (setq Dist (vlax-curve-getDistAtParam Vl-Obj Index ) )
    (setq Level (rtos (+ StartLevel (* Gradient Dist )) 2 3 ) )
    (setq Point (vlax-curve-getPointAtParam Vl-Obj Index ) )
    (command "._text" "J" "MC" Point "10" "0" Level )
  )
  (princ)
)

: ) Happy Computing !

kennet

These are the changes i made. Thank you for helping me. The main thing I learnt is to find a complete list of commands that you can do in a lisp and what they do. I found this (somewhere on the net) and it helped me alter your lisp to this...

(defun c:ilp ( / StartLevel Gradient Poly Vl-Obj #Vertex Index Dist Level Point )
  (setq StartLevel (getreal "Please choose the Start Invert : ") )
  (setq Gradient (getreal "Please choose the Grade : ") )
  (setq Poly (entsel "Please choose the polyline : " ) )
  (vl-load-com)
  (setq Vl-Obj (vlax-ename->vla-object (car Poly )) )
  (setq #Vertex (fix (vlax-curve-getEndParam Vl-Obj )) )
  (setq Index -1 )
  (repeat (1+ #Vertex )
    (setq Index (1+ Index ) )
    (setq Dist (/ (vlax-curve-getDistAtParam Vl-Obj Index) 1000) )
    (setq Level (rtos (- StartLevel (* Gradient Dist )) 2 3 ) )
    (setq Point (vlax-curve-getPointAtParam Vl-Obj Index ) )
    (command "-layer" "set" "HYD-iNverts" "" "_text" "J" "BL" Point (* 1 dwgscale) "45" Level )
  )
  (princ)
)

[kennet.sjoberg]

I am glad if I helped you, and also glad that you have learned something.

Not all, but a lot of Commands can you find "inside" AutoCAD
Type Command: VLIDE to start the Visual LISP editor
Click the icon “New File” in the upper left corner
Type in the <Untitled-1> window ( you make your program code here )
cond as an example ( and it will be coloured in blue )
double click cond to make it background marked
click the help [ ? ] button, and it will take you to the
Developer Documentation AutoLISP Function cond

: ) Happy Computing !

kennet