DCL's for dummy

[gfreddog]

I noticed some LISP's on this forum that also require a DCL file.

In previous threads I have also seen what DCL's do explained.

But my question is how do I load them or where do I save them?

(Be gentle I'm a mediocre LISPer)

[T.Willey]

The dcl file just has to be in the search path. The code will try and load the file from the search path, and it it's found it will try and load the dialog box from said file.

(setq DiaLoad (load_dialog "MyDialogs.dcl"))
(new_dialog "MultiSelect" DiaLOad)

This loads the dialog called ' MultiSelect ' from the dialog file ' MyDialogs.dcl '. It is in the search path, therefore I don't need a fully qualified path to it. You might want to look at what those two dialog functions do ( load_dialog new_dialog ) as it has been a long time since I looked at them in the help.

[gfreddog]

Ah okay. So I have a folder for my LISPs and as long as the DCL is in the same folder AND that folder is in the AutoCAD Search Path it will see it.

Thanks for the clarifications

[andrea.andreetti]

you can also specify the path...

(setq DiaLoad (load_dialog "x:\\my dialogs\\MyDialogs.dcl"))

[gfreddog]

you can also specify the path...

(setq DiaLoad (load_dialog "x:\\my dialogs\\MyDialogs.dcl"))

Merci mon ami utiles, Ma famille est originaire de Québec (and my french is very limited living in Joisey! )

[andrea.andreetti]

Merci mon ami utiles, Ma famille est originaire de Québec (and my french is very limited living in Joisey! )

i was born in Italy....but I live in Quebec. enchanté !

[CadDog]

Merci mon ami utiles, Ma famille est originaire de Québec (and my french is very limited living in Joisey! )

That shows you can't judge a person my his/her icon, location, etc...



I thought he was a wonder kid...
So young and yet able to type so nicely...

[andrea.andreetti]

you can also take a look here...

http://web2.airmail.net/terrycad/Tut.../MyDialogs.htm

[irneb]

Another thing you could do is to combine the LSP & DCL files into a VLX file (using VLISP). Then simply loading the VLX loads both the LSP & DCL ... no need for paths. Easy way of running some special code that you don't want to have cluttering the rest of your lisp paths.

[_gile]

Hi,

Another way is to write the DCL from the LISP in a temporary file.
Here's a little example:

;; ListBox (gile)
;; Dialog box which allows a single or multple choice
;;
;; Arguments:
;; title : dialog title (string)
;; msg ; message (string), "" or nil for none
;; keylab : assoc list which type is ((key1 . label1) (key2 . label2) ...)
;; flag : 0 = popup list
;;        1 = single choice list
;;        2 = multiple choice list
;;
;; Return : the key of the choosen option (flag = 0 or 1) or the key list (flag = 2)
;;
;; Example:
;; (listbox "Layout" "Choose a layout" (mapcar 'cons (layoutlist) (layoutlist)) 1)

(defun ListBox (title msg keylab flag / tmp file dcl_id choice)
  (setq	tmp  (vl-filename-mktemp "tmp.dcl")
	file (open tmp "w")
  )
  (write-line
    (strcat "ListBox:dialog{label=\"" title "\";")
    file
  )
  (if (and msg (/= msg ""))
    (write-line (strcat ":text{label=\"" msg "\";}") file)
  )
  (write-line
    (cond
      ((= 0 flag) "spacer;:popup_list{key=\"lst\";")
      ((= 1 flag) "spacer;:list_box{key=\"lst\";")
      (T "spacer;:list_box{key=\"lst\";multiple_select=true;")
    )
    file
  )
  (write-line "}spacer;ok_cancel;}" file)
  (close file)
  (setq dcl_id (load_dialog tmp))
  (if (not (new_dialog "ListBox" dcl_id))
    (exit)
  )
  (start_list "lst")
  (mapcar 'add_list (mapcar 'cdr keylab))
  (end_list)
  (action_tile
    "accept"
    "(or (= (get_tile \"lst\") \"\")
    (if (= 2 flag) (progn
    (foreach n (str2lst (get_tile \"lst\") \" \")
    (setq choice (cons (nth (atoi n) (mapcar 'car keylab)) choice)))
    (setq choice (reverse choice)))
    (setq choice (nth (atoi (get_tile \"lst\")) (mapcar 'car keylab)))))
    (done_dialog)"
  )
  (start_dialog)
  (unload_dialog dcl_id)
  (vl-file-delete tmp)
  choice
)

;; STR2LST
;; Transforms a string with separator into a list of strings
;;
;; Arguments
;; str = the string
;; sep = the separator pattern
(defun str2lst (str sep / pos)
  (if (setq pos (vl-string-search sep str))
    (cons (substr str 1 pos)
	  (str2lst (substr str (+ (strlen sep) pos 1)) sep)
    )
    (list str)
  )
)

This way, allows to create the dialog box differently according to parameters got by the LISP before writing the file.
In the attached file, SSD is used to make a dynamic blocks selection filtered by their dynamic properties. The dialog box to choose the properties is created after the choice of a target block and matches its dynamic properties.