How to enter relative length AND relative angle?

[Yancka]

@Length<Angle concept is clear. Is it possible to enter something like relative Length (with @10) and value of angle which is relative to previously used angle?
For example, I draw a line from 0,0; for next point I enter @10<21; and next line has to be drawn in angle which is 44 degrees realitve to previously drawn lines 10 units long. OK, I can do calculation 21+44=65 and make entry @10<65 but I don't want to do this calculation.

Polar tracking relative to last segment is fine in cases when angles are typical. If angles aren't typical then there's no use of it.

At the moment I don't see other option than to make a custom command (LISP or whatever) that somehow does "last segment angle + current segment relative angle" calculation. Any other ideas?

[irneb]

You mean you're looking for something like that old (80's) Turtle Graphics?

Turn 21 Move 10 Turn 44 .....

No sorry, I don't think AC has that! I can imagine a Lisp being able to do something like this, maybe someone's done it before?

[duhvinci]

There is a way to do this but you need to go into an editing mode rather than a "draw" mode.

After you have drawn your first segment, exit the command. Now select the line just created and perform a "grip" copy, rotate, scale using the references and base point options that are available.

It will take practice but it can be an efficient way to do what you are looking for

[jaberwok]

You mean you're looking for something like that old (80's) Turtle Graphics?

Turn 21 Move 10 Turn 44 .....

No sorry, I don't think AC has that! I can imagine a Lisp being able to do something like this, maybe someone's done it before?

That's one good uStation idea that adesk haven't copied.

[Julesagain]

You can add custom angles to the polar tracking, but if your angles are always atypical this won't help

jules

[irneb]

Here's a quick and dirty custom line command which changes the UCS to have the X axis on the same angle as the last line segment drawn:

;;; Draw line while changing UCS to allow relative angles
(defun c:LineRel (/ pt1 pt2 elst en ed)
  (command "._undo" "_BEgin")
  (command "._ucs" "_World")
  (while (and
           (/= pt1 "Exit")
           (or (initget "Exit Undo")
               (and pt2
                    (setq pt1 pt2
                          pt2 (getpoint pt1 "\nPick start point [Exit/Undo] <Exit>: ")
                    ) ;_ end of setq
               ) ;_ end of and
               (setq pt1 (getpoint "\nPick start point [Exit/Undo] <Exit>: "))
           ) ;_ end of or
         ) ;_ end of and
    (cond
      ((and (= (type pt1) 'LIST) (or pt2 (setq pt2 (getpoint pt1 "\nPick next point: "))))
       (command "._line" pt1 pt2 "")
       (setq elst (cons (entlast) elst))
       (command "._ucs" "_World")
       (command "._ucs" "_Z" (angtos (angle pt1 pt2)))
       (setq pt2 (trans pt2 0 1))
      )
      ((= pt1 "Undo")
       (if (setq en (cadr elst))
         (progn
           (setq ed  (entget en)
                 pt2 (cdr (assoc 11 ed))
           ) ;_ end of setq
           (setq en   (car elst)
                 elst (cdr elst)
           ) ;_ end of setq
           (entdel en)
           (command "._ucs" "_Previous")
           (command "._ucs" "_Previous")
           (setq pt2 (trans pt2 0 1))
         ) ;_ end of progn
         (if (setq en (car elst))
           (progn
             (entdel en)
             (command "._ucs" "_Previous")
             (command "._ucs" "_Previous")
             (setq pt2 nil)
           ) ;_ end of progn
           (setq pt2 nil)
         ) ;_ end of if
       ) ;_ end of if
      )
    ) ;_ end of cond
  ) ;_ end of while
  (command "._undo" "_End")
  (princ)
) ;_ end of defun

It's not working perfectly, some tweaking needs to be done, but it gives an idea.