LISP NEEDED - Copy attribute and paste as single line text

[ECASAOL350033]

Hi Guys,

Just need some help with a lisp routine. I have honestly no idea of how to start one but i am able to modify what is made.
Basically, what i need is a routine the copy's the value of the attribute then pastes the value as a (separate) single line text next to it. Simple routine though some of you guys are there are wizards at this stuff.....

Thanks!

Rico

[rfrance]

Not exactly what you asked for but closest thing I have. This will copy from an attribute to existing single line text or vice versa or text to text or att to att - doesn.'t care but both have to be existing. You could tweak it to create the new line of text though pretty easily.

;Command Name Is TXTCOPY
(defun c:txtcopy ( / PRM1 PRM2  TCF TCT TMP)
	(alpha)
              (setq TMP '("TEXT" "ATTRIB")
                       PRM1 "\nSelect text to copy from: "
                       PRM2 "\nINVALID: Entity selected must be an attribute or single line text!"
              )
	(while t
		(while (not (member (ecinf (setq TCF (car (nentsel PRM1))) 0) TMP))
			(prompt PRM2)
		)
		(while (not (member (ecinf (setq TCT (car (nentsel PRM1))) 0) TMP))
			(prompt PRM2)
		)
		(modent TCT 1 (ecinf TCF 1))
		(if (= (ecinf TCT 0) "ATTRIB") (attupd TCT))
	)
	(omega))


;This is a set of standard routines I use A LOT.

;ALPHA sets a couple of variables and sets the error to run OMEGA if the command is canceled.
(defun ALPHA ()
	(defun *error* (MSG)
		(if (/= MSG "Function cancelled")
			(princ (strcat "\nerror: " MSG))
		)
		(omega)
	)
	(sv '("cmdecho" "attdia") 0 t)
)

;ECINF just gets the entity code info needed
(defun ECINF (EN EC)
	(if (= (type EN) 'ENAME)
		(cdr (assoc EC (entget EN)))
		(cdr (assoc EC EN))
)	)

'MODENT modifys the entity code
(defun MODENT (EN EC EV)
	(entmod (subst (cons EC EV) (assoc EC (entget EN)) (entget EN)))
)

;SV is a standard routine that saves the current setting of variables to a list for resetting with OMEGA and sets them per ALPHA
(defun SV (VN V? AL / CV)
	(while VN
		(if (and	 (not (member (setq CV (car VN)) VL))	 (= AL t))
			(setq VL (append VL (list CV (getvar CV))))
		)
		(setvar CV V?)
		(setq VN (cdr VN))
)	)

;OMEGA resets all the variables set by SV
(defun OMEGA ()
	(while VL (setvar (car VL) (cadr VL)) (setq VL (cddr VL)))
		(setq CMMAND nil)
	)
(princ))

Rick France
Solutions Engineer
Hagerman & Company

[pbejse]

Hi Guys,
what i need is a routine the copy's the value of the attribute then pastes the value as a (separate) single line text next to it.....

Thanks!

Rico

A simple solution:

(defun c:demo ()
(vl-load-com)  
  	(if (and (setq att (Car (nentselp "\nSelect Attribute: ")))
                (eq (cdr (Assoc 0 (setq en (entget att)))) "ATTRIB"))
	(progn
          	(Setq data (cons '(0 . "TEXT") (vl-remove-if-not '(lambda (x)
                                     	(member (car x) '( 1 10 7 8  41 40 50))) en)))
          	(entmakex data)
          (command "_move" (entlast) "" "_non" (Cdr (caddr data)) pause)
          )))

[fixo]

Awesome,
Kind regards,

[Bababarghi]

A simple solution:

(defun c:demo ()
(vl-load-com)  
  	(if (and (setq att (Car (nentselp "\nSelect Attribute: ")))
                (eq (cdr (Assoc 0 (setq en (entget att)))) "ATTRIB"))
	(progn
          	(Setq data (cons '(0 . "TEXT") (vl-remove-if-not '(lambda (x)
                                     	(member (car x) '( 1 10 7 8  41 40 50))) en)))
          	(entmakex data)
          (command "_move" (entlast) "" "_non" (Cdr (caddr data)) pause)
          )))

Can it be customised in a way to let user select multiple attributes at the same time (from several blocks maybe) ?

[pbejse]

Awesome,
Kind regards,

Thank you Oleg

Can it be customised in a way to let user select multiple attributes at the same time (from several blocks maybe) ?

Yes, it can be done.

[Bababarghi]

Yes, it can be done.

I actually meant 'how' ?!

[pbejse]

I actually meant 'how' ?!

I know that Bababarghi
Here's "How"

- wrap the nentselp prompt inside a while function
- process each item of selected ATTRIB with foreach using the method on the previous code
- change the (enlast) to a selection set <from the process> on the move command

Will that work for you?


As for the CODE: I would want you to try and figure it out from the "how" statement above before you take a peek at the code below [Don't scroll down <Spoiler>]

(defun c:demo (/ attr_ att data en)
  (vl-load-com)
  (setq attr_ nil)
  (while
    (and (princ	(strcat	"\nCurrent number of selected attribute: "
			(itoa (length attr_))
		)
	 )
	 (setq att (Car (nentselp "\nSelect Attribute: ")))
	 (eq (cdr (Assoc 0 (setq en (entget att)))) "ATTRIB")
    )
     (setq attr_ (cons en attr_))
  )
  (if attr_
    (progn
      (setq attrss (ssadd))
      (foreach _att attr_
	(Setq data (cons '(0 . "TEXT")
			 (vl-remove-if-not
			   '(lambda (x)
			      (member (car x) '(1 10 7 8 41 40 50))
			    )
			   _att
			 )
		   )
	)
	(ssadd (entmakex data) attrss)
      )
      (command "_move" attrss "" "_non" (Cdr (caddr data)) pause)
    )
  )
  (princ)
)

[Bababarghi]

I know that Bababarghi
Here's "How"

- wrap the nentselp prompt inside a while function
- process each item of selected ATTRIB with foreach using the method on the previous code
- change the (enlast) to a selection set <from the process> on the move command

Will that work for you?


As for the CODE: I would want you to try and figure it out from the "how" statement above before you take a peek at the code below [Don't scroll down <Spoiler>]

Thanks PMpbejse. I liked your approach. I reckon you are, or have been, a teacher - at least at some stages of your career !

I am so-called an absolute 'beginner' when it comes to LSP programming but I am sure I can handle it soon or late.

Just one more massage request for the code: How can I select my desired attributes by a crossing window?

[pbejse]

Thanks PMpbejse
Just one more massage request for the code: How can I select my desired attributes by a crossing window?

To be on the clear, you are wanting to select a specific attribute in a block with as "crossing window" but not necessarily ALL the attdefs on that block?

(Defun c:CAt (/ attr_ ss e n data attrss)
;;;	pBeFeb2014	;;;
  (if (setq attr_ nil
	    ss	  (ssget '((0 . "INSERT") (66 . 1)))
      )
    (progn
      (repeat (setq i (sslength ss))
	(setq n (entnext (ssname ss (setq i (1- i)))))
	(while (not (eq (cdr (assoc 0 (setq e (entget n)))) "SEQEND"))
	  (if (/= (cdr (assoc 1 e)) "")
	    (setq attr_ (cons e attr_))
	  )
	  (setq n (entnext n))
	)
      )
      (if attr_
	(progn
	  (setq attrss (ssadd))
	  (foreach _att	attr_
	    (Setq
	      data (cons '(0 . "TEXT")
			 (vl-remove-if-not
			   '(lambda (x)
			      (member (car x) '(1 10 7 8 41 40 50))
			    )
			   _att
			 )
		   )
	    )
	    (ssadd (entmakex data) attrss)
	  )
	  (command "_move" attrss "" "_non" (Cdr (caddr data)) pause)
	)
      )
    )
  )
  (princ)
)