Dynamic function definition

[JaCAD]

Hey all,

I've been able to write a function that dynamically created variables and stored values.

(defun GetAndStoreVariables ( / );Get and set variable values for functional stuff
  (foreach Pair (SomeVariables)
    (set (read (car Pair)) (cdr Pair))
    );end foreach
  (princ)
  );end defun

(defun SomeVariables ( / )
    (list (cons "Var1" 123)
          (cons "Var2" 456)
          (cons "FrameWid" 1200.0)
          (cons "StandardSpacing" 100.0)
          )
   );end defun

Does anybody know if it's possible to dynamically define functions?
I'm currently trying the following:

(setq Cnt 0)

(while (< (setq Cnt (1+ Cnt)) 10)
   (defun (read (strcat "C:" (itoa Cnt))) ( / )
         (body of function......)
         );end defun
    );end while

But I keep getting "Syntax Error".

Any thoughts?

[alanjt]

Here's one I did looong ago...

;fillet with set radius
;Alan J. Thompson
(mapcar
  '(lambda (f r)
     (eval (list 'defun
         f
         nil
         (list 'setvar "filletrad" r)
         (list 'princ (strcat "\nFillet radius set to: " (rtos r)))
         (list 'command "_.fillet")
         '(princ)
       )
     )
   )
  '(c:FF    c:F1    c:F15    c:F2    c:F3    c:F4    c:F45    c:F5    c:F6    c:F7    c:F8    c:F9)
  '(0        1    1.5    2    3    4    4.5    5    6    7    8    9)
)

[JaCAD]

Thanks for the kick-start Alanjt. I got it working!

(setq Cnt 0)
(while (< (setq Cnt (1+ Cnt)) 10)
  (eval (list 'defun
                (read (strcat "C:" (itoa Cnt)))
		nil
		(list 'SetLayer (read (strcat "LAY:Detl" (itoa Cnt))))
		'(princ)
		);end list
	  );end eval
    );end while

[alanjt]

Thanks for the kick-start Alanjt. I got it working!

(setq Cnt 0)
(while (< (setq Cnt (1+ Cnt)) 10)
  (eval (list 'defun
                (read (strcat "C:" (itoa Cnt)))
        nil
        (list 'SetLayer (read (strcat "LAY:Detl" (itoa Cnt))))
        '(princ)
        );end list
      );end eval
    );end while

Glad to hear. You're welcome.